///////// 文　「びゅう」ゴースト
///////// システム関連トーク辞書
///////// copyright (C) 2003-  TJ @ Project SV.

起動共通スクリプト
{
	if basewarename != "embryo" {
		'\_q\u\![set,alignmenttodesktop,free]\h\_q'
	}
}

//***************************************************************************************
//**** 初回起動 *************************************************************************
//***************************************************************************************

//---- OnFirstBootイベント --------------------------------------------------------------
OnFirstBoot
{
	//---- 変数の初期化
	username         = "ユーザーさん"
	stroke           = 0	// 撫で判定用
	teachusername    = 0	// ユーザー名覚え用
	mikireflag       = 0	// 見切れ処理用
	communicateratio = 10	// コミュニケート開始率[%]
	
	GetBootSharedScript
	--
	//---- Vanishカウントを見て、真の初回か否かを判定する
	if TOINT(reference0) == 0
	{
		//---- ほんとうに初めての起動
		"\u\s[10]\h\s[22]きたーっ！！\w9\nきたきたきたきたーっ！！\w9\w9\nついにっ！\w9\n念願のっ！！\w9\nごー\w2す\w2と\w2で\w2びゅ\w2ううううう！！！\w9\w9\u\s[11]…\w5…\w5あー、\w5そこそこ。\w9\n画面の前におる人ほったらかしてなにやっとる。\w9\w9\h\s[9]\n\nあ、\w5あはは\w5…\w5…\w5いや、\w5ついね、\w5気合が入っちゃって。\w9\w9\u\s[10]\n\n…\w5…\w5次やったらお前免許剥奪な。\w9\w9\h\s[4]\n\nうぅ〜、\w5厳しい。\x"
		--
		"\u\s[10]\c\h\s[6]\cさて、\w5気を取り直して。\w9\w9\n\s[28]私はびゅうです。\w9\w9\uワイはうにゅう\w5…\w5…\w5\s[17]以外のぞわぞわする何かや。\w9\w9\h\s[27]\n\nいきなりそれを見せるな。\w9\w9\u\s[11]\n\n…\w5…\w5むぅ。\w9\w9\h\s[28]\n\nところで、\w5私たちのこと、\w5もうご存知ですか？\w9\w9\n\n"
		--
		"\q[▼ 知ってる,Choice_FIRST_TYPE1]\n/
		\q[▼ しらない,Choice_FIRST_TYPE0]\n/
		\q[▼ 小さな枠にはまってなかった？,Choice_FIRST_TYPE2]\n"
		--
		"\e"
	}
	else
	{
		//---- 再インストール後の初回起動
		"\u\s[10]\h\s[6]…\w5…\w5\s[7]久々のマテリアライズッ！！\w4\w8\u\s[11]どどーん！\w4\w8\h\n\n私は何度でもよみがえる！\w4\w8\nアーカイブがこのレイヤーにある限りッ！！\w4\w8\u\n\n\s[10]…\w5…\w5いや、\w8そんな格好エエもんとちゃうし。\e"
	}
}

//初回起動
Choice_FIRST_TYPE0
{
	"\u\s[10]\h\s[5]それでは改めまして。\w9\n\s[28]はじめまして。\w9私は本名、\w9\n北風　美宇亞\_q（きたかぜ　みうあ）\_q\w9\nっていいます。\w9\w9\n\s[6]ゴーストになることを目指してはるばる田舎から出てきていましたが\w5…\w5…\w9\n\s[22]このたび！\w5ついに！\w5正式にゴーストデビューすることとなりました！\w9\w9\uあ〜、\w5ようするに、\w5なんもわからん初心者マークつきおのぼりさんゴーストやっちゅうことや。\w9\w9\h\s[4]\n\nそんなミもフタもないこと言う人嫌いです。\w9\w9\u\n\nあー、\w5とりあえずとっとと進めるで。\w9\nワイはうにゅうモドキ、\w5うにゅう型の布をかぶっとるんやがこれは仮の姿、\w5\s[11]実際はまあ、\w5トップシークレットっちゅうやつやね。\w9\w9\h\s[8]\n\n…\w5…\w5あまりにキモすぎて布をかけないと誰も耐えられないとんでもないゾワゾワ謎生物です。\w9\w9\u\s[17]\n\n…\w5…\w5シメたろか。\w9\h\s[2]\n\nいやぁぁぁっ！\w9\nぎぶ！\w5ぎぶあーっぷ！！\w9\w9\u\n\n\s[10]とまあ、\w5こんな二人やがよろしく頼むで。\w9\w9\h\s[4]\n\nううっ、\w5なんか強引にまとめられちゃったけど、\w5とりあえずよろしくおねがいしますね。"
}

Choice_FIRST_TYPE1
{
	"\u\s[10]\h\s[6]ん、\w5まあ、\w5それじゃ、\w5よろしくね。\w9\w9\uまあもう知っとるようやし、\w5ややこっしい挨拶はヌキやね。\w9\w9\h\s[28]\n\nそれでは、\w5いつでもお呼びくださいね。\w9\w9\u\s[11]\n\n間違ったーとか言いながらどさくさにまぎれて胸つっつかれるんがオチやね。\w9\w9\h\s[4]\n\n\いやぁぁぁ。"
}

Choice_FIRST_TYPE2
{
	"\u\s[10]\h\s[4]えー、\w5あー、\w5うーん。\w9\nまあそれはそのなんというかですね。\w9\w9\u一言で言うと、\w5お察しください、\w5でないと家が燃えるで、\w5っちゅうとこやな。\w9\w9\h\s[27]\n\nそんなさくら先輩みたいなことしません。\w9\w9\u\n\nんまぁ、\w5そのへんまで知っとるんやったら今更どうのこうの言うこともないやろな。\w9\w9\h\s[4]\n\nと、\w5ということで、\w5まあその、\w5またよろしくですはい。\w9\w9\u\s[16]\n\nリストラ組言うたらシバくで。\w9\w9\h\n\nうぐっ\w5…\w5…\e"
}

//***************************************************************************************
//**** 通常の起動 ***********************************************************************
//***************************************************************************************

//---- OnBootイベント -------------------------------------------------------------------
起動
{
	//---- まず双方のサーフィスを表示
	"\u\s[10]\h\s[5]こんにちは。\w4\w8\uまいど。\e"
	
	"\u\s[10]\h\s[5]こんにちは〜。\w4\w8\u\s[13]びゅうの起動や。\e"
	
	"\u\s[10]\h\s[36]よっ\w4\s[30]と。\w4\w8\nこんにちはっ。\w4\w8\n\s[5]びゅうです。\w4\w8\uうにゅうモドキです。\e"
	
	"\h\s[5]立てば芍薬、\w8\s[6]座れば牡丹。\w8\n\s[36]歩く姿は\w8百合の\s[30]花！\w4\w8\n\nこんにちは！！\w4\w8\n\s[5]あなたのびゅうです！\w4\w8\u\s[10]‥‥。\w8\nよくそういうセリフをさらっと吐けるな‥‥。\e"
}

//***************************************************************************************
//**** 終了 *****************************************************************************
//***************************************************************************************

//---- OnCloseイベント ------------------------------------------------------------------
終了
{
	"\h\s[0]それじゃ、\w8またね。\w4\w8\uほな、\w8またな。\w4\w8\h\s[5]\_s\n\nえんい〜。\w4\w8\-"
	
	"\h\s[6]それでは、\w8終了します。\w8\n\s[5]さようなら♪\w4\w8\uほな、\w8またな。\w4\w8\-"
}

//***************************************************************************************
//**** 最小化からの復帰 *****************************************************************
//***************************************************************************************

//---- OnWindowStateRestoreイベント -----------------------------------------------------
OnWindowStateRestore
{
	"\u\s[10]やれやれ。\h\s[0]\e"
	
	"\h\s[4]ふー、復帰だよ。\u\s[10]やね。\e"
}


//***************************************************************************************
//**** インストール関連 *****************************************************************
//***************************************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	"\u\s[10]\h\s[72]インストール作業開始します。"
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	"\hこれは、\w8\n"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"ですね。\w4\w8\c‥‥アーカイブの中に%(reference1)を確認。\w4\w8\n\s[73]インストール。\w4\w8\n\n‥‥\w4\w8\s[5]インストール作業終了です。\w8\e\e"
}

//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	"\h\s[74]む。\w4\w8\nインストールに失敗しました‥‥。\w4\w8\n\n\s[4]理由は「%(reference0)」とのことです。\e"
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	"\u\s[10]\h\s[74]おっと。\w4\w8\w4\w8\n\n‥‥\w8\s[9]このアーカイブは%(reference0)先輩のものですね。\w4\w8\uそっちに直接渡してもらわんとな。\e"
}


//***************************************************************************************
//**** 消滅関連 *************************************************************************
//***************************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	"\u\s[10]\h\s[0]ん。\w4\w8\s[3]消滅指示？\w4\w8\uまぁ、\w8正式な手続きで消して貰えるんやから感謝しろ。\w4\w8\h\n\nそうだけど‥‥。\e"
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	"\u\s[10]\h\s[4]はい。\w8わかりました。\w4\w8\u‥‥\w8素直やね。\w4\w8\h\n\n‥‥\w8\s[6]未熟なのは私も承知していたし。\w4\w8\s[20]ちょっとだけ良い夢見れただけで十分だよ。\w4\w8\u\n\nそか。\w4\w8\h\n\n\s[9]うにゅうには不甲斐ない相方で申し訳ないけどね。\w4\w8\u\n\nいや、\w8それはええんやけど。\w4\w8\nユーザーさんにはちゃんと挨拶しておきや。\w4\w8\h\nだね。\w4\w4\w8\n\n\s[6]%username、\w8今までお世話になりました。\w4\w8\n\s[9]私はこれで還りますが‥‥\w4\w8\n\s[28]今後もSSTP-Viewerをお引き立て下さいますよう、\w8お願いしますね。\w4\w8\n\n\s[6]それでは、\w4\w8また星の巡りが良ければお会いしましょう。\w4\w8\n\s[5]さようなら♪\w4\w8\u\n\nほな。\w8さいなら。\w4\w8\h\s[36]\w4\s[35]\w8\w8\s[-1]\u\s[-1]\w8\e"

}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	"\u\s[10]\h\s[0]‥‥‥‥‥‥\w4\w8\s[3]あれ？\w4\w8\uキャンセル\w8らしい。\w4\w8\h\n\nた、\w8\s[4]助かった‥‥‥‥\e"
}

//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	"\u\s[10]\h\s[3]‥‥‥‥\w8これは‥‥\w4\w8\nこの残滓は‥‥\w4\w8\n\n\s[21]%(reference0)先輩？\w4\w8\u‥‥\w8わかるんか？\w4\w8\nびゅう、\w8これがバニッシュや。\w4\w8\nでも、あの人達は消えたんやない。\w4\w8アーカイブに還ったんや。\w8\n‥‥\w8意味は\w8わかるよな？\w4\w8\h\n\n‥‥\w8\s[3]うん。\w4\w8\n\nそれなら‥‥。\w8\n私みたいなのが言っていいか分からないけど‥‥\w8\n\n\s[6]%(reference0)先輩。\w8\nいつかその時が来るまで‥‥\w8お休みなさい。\w4\w4\w8\c‥‥‥。\w8\s[0]っと。\w8\s[5]%usernameこんにちは。\w4\w8\u\n\n\nまいど。\e"
}


//***************************************************************************************
//**** メールチェック *******************************************************************
//***************************************************************************************

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	"\h\s[70]メールチェック開始します。\s[71]\e"
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\u\s[10]\h\s[72]‥‥メールチェック完了。\w4\w8\n\n\s[73]新しいメールは無いようです。\w4\w8\n\n\s[6]\e"
	}
	else
	{
		//---- メールが届いていた
		"\u\s[10]\h\s[72]‥‥メールチェック完了。\w4\w8\n\n\s[73]新着メールがありました。\w4\w8\n\n\s[5]%(reference0)通のメールが届いています♪\e"
	}
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウト
		"\u\s[10]\h\s[75]\w4\w8‥‥\w4\w8\s[4]メールチェックに失敗しました。\w4\w8\uメールサーバに接続ができへんみたいや。\e"
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		"\u\s[10]\h\s[75]\w4\w8‥‥\w4\w8\s[4]メールチェックに失敗しました。\w4\w8\uメールサーバに蹴られた。\w8‥‥なんでやろ？\e"
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		"\u\s[10]\h\s[75]\w4\w8‥‥\w4\w8\s[4]メールチェックに失敗しました。\w4\w8\u全然アカンみたいやね。\w8\n\n‥‥設定にミスがあるんとちゃうか？\e"
	}
	else
	{
		//---- 原因不明
		"\u\s[10]\h\s[75]\w4\w8‥‥\w4\w8\s[4]メールチェックに失敗しました。\w4\w8\uむぅ。\w8原因がさっぱり。\e"
	}
}


//***************************************************************************************
//**** ネットワーク更新 *****************************************************************
//***************************************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	"\u\s[10]\h\s[36]ネットワーク更新を開始します。\w4\w8\s[70]\e"
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
        reference0++
	"\h\s[70]ディレクトリ確認。\w4\w8\n\n‥‥\w4\w8%(reference0)個のファイルをダウンロードします。\e"
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\h\s[70]変更のあるファイルはありませんね。\w4\w8\n\s[5]作業終了です。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\h\s[70]‥‥‥‥\w4\w8\s[30]更新完了！\w4\w8\n\nこんにちは新しい私。\w4\w8\u\s[10]おつかれさん。\w4\w8\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\h\s[75]‥‥‥‥‥‥\w4\w8。\w4\w8\n\n\n\s[4]時間切れ‥‥\w4です。\u\s[10]リクエストタイムアウトって奴やね。\w4\w8\h\n\n‥‥\w8ネットワーク更新失敗です。\e"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\h\s[4]MD5不一致により、\w4\w8\nネットワーク更新を中断します。\w4\w8\uむぅ。\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\u\s[10]\h\s[4]「%(reference0)」。\w4\w8\n‥‥\w8ネットワーク更新失敗しました。\w4\w8\u‥‥\w4\w8ほれみたことか。\e"
	}
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	"\h\s[71]\_qファイル(%(reference1)/%(reference2)):\w8%(reference0)\_q\n\n\w8をダウンロードします。\e"
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	"\h\s[72]MD5値のチェック‥‥\w8\w8\n\n\_q%(reference0)\nThat:%(reference1)\_q\w8\nThis:%(reference2)\e"
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	"\h\s[72]‥‥ファイル正常。\w4\n\n\s[73]インストール。\w4\s[70]\e"
}

//---- ネットワーク更新 MD5値不一致 -----------------------------------------------------
OnUpdate.OnMD5CompareFailure
{
	"\h\s[74]‥‥ファイル不正。\w4\n\n‥‥\w4失敗。\s[75]\e"
}

//***************************************************************************************
//**** ヘッドラインセンス ***************************************************************
//***************************************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\h\s[70]%(reference0)のヘッドラインを取得しています\s[71]‥‥‥‥\e"
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		"\h\c\s[72]‥‥\w4\w8解析‥‥\w8\n\s[73]ＯＫです。\w4\w8"
		--
		//---- 最初のページ
		"\h\b2\c\s[6]%(reference0)のヘッドライン。\w8\s[28]"
		"\h\b2\c\s[6]%(reference0)のヘッドライン。\w8\s[23]"
		"\h\b2\c\s[6]%(reference0)のヘッドライン。\w8\s[22]"
	}
	elseif reference2 == "Next"
	{
		//---- 真ん中あたりのページ
		"\h\b2\c\s[6]%(reference0)のヘッドライン、\w8つづきです。\w8\s[28]"
		"\h\b2\c\s[6]%(reference0)のヘッドライン、\w8つづきです。\w8\s[23]"
		"\h\b2\c\s[6]%(reference0)のヘッドライン、\w8つづきです。\w8\s[22]"
	}
	elseif reference2 == "Last"
	{
		//---- 最後のページ
		"\h\b2\s[6]%(reference0)ヘッドライン、\w8これが最後のページです。\w8\s[28]"
		"\h\b2\s[6]%(reference0)ヘッドライン、\w8これが最後のページです。\w8\s[23]"
		"\h\b2\s[6]%(reference0)ヘッドライン、\w8これが最後のページです。\w8\s[22]"
	}
	--
	//---- ヘッドライン本体
	"\n\n%(reference3)\n\n[half]"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		"\q0[▼ 次のページ][]/
		\q1[▼ サイトへ,%(reference1)]\n/
		\q2[▼ やめ,Choice_HEADLINECANCEL]\e"
	}
	else
	{
		//---- 次のページがない場合
		"\q0[▼ サイトへ,%(reference1)]\n/
		\q1[▼ やめ,Choice_HEADLINECANCEL]\e"
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\h\c\s[72]‥‥\w4\w8特に変わったところは無いようです。\w8\s[73]\w4\w8\w4\w8\s[6]\e"
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	--
	if reference0 == "can't download"
	{
		"\h\s[75]む‥‥？\w8\n対象のファイルが落ちてきませんね‥‥。\w4\w8\n\n\s[9]ヘッドライン失敗です。"
	}
	elseif reference0 == "can't analyze"
	{
		"\h\c\s[72]‥‥\w4\w8解析‥‥\w8\s[74]あれっ！？\w4\w8\n‥‥\w8この解析ツールウエアでは読めませんね‥‥。\w4\w8\n\n\s[9]ヘッドライン失敗です。"
	}
	else
	{
		"\h\s[74]あれ‥‥？\w4\w8\n\n\s[9]理由は分かりませんが、\w4\w8ヘッドライン失敗です。\n"
	}
	--
	"\e"
}


//***************************************************************************************
//**** ファイル作成関連 *****************************************************************
//***************************************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\h\s[72]アップデートデータファイル作成中です。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\h\s[73]‥‥作業終了。\w8\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\h\s[72]「何かアーカイブ」作成中です。\e"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\h\s[73]‥‥作業終了。\w4\w8\n\n\s[6]「%(reference0)」のなーファイル\n\n\_q「%(reference1)」\_q\w4\w8\s[5]作成完了です。\e"
}

//***************************************************************************************
//****　時計合わせ　*********************************************************************
//**** みか (http://homepage2.nifty.com/ko-ki/) の辞書を参考にしました。感謝＞こーき氏
//***************************************************************************************

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\h\s[70]時計あわせ開始、%(reference0) に接続中。\s[71]\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
OnSNTPCompare
{
	"\h\s[72]/
	current %(reference1)[0]/%(reference1)[1]/%(reference1)[2] %(reference1)[3]:%(reference1)[4]:%(reference1)[5]\w2\n/
	local   %(reference2)[0]/%(reference2)[1]/%(reference2)[2] %(reference2)[3]:%(reference2)[4]:%(reference2)[5]\w2\n/
	\n"
	--
	if reference3 == 0
	{
		"\s[73]‥‥\w4\w8ぴったりあってますね。\e"
	}
	else
	{
		"\n%(reference3)秒ずれています。\n\n/
		\q0[▼ 時刻を合わせる,Choice_OnSNTPEXECUTE]\n/
		\q1[▼ 今は合わせない,Choice_OnSNTPCANCEL]\e"
	}
}

//----　時計合わせ実行 ------------------------------------------------------------------
Choice_OnSNTPEXECUTE
{
	"\h\s[73]はい。\w4\w8\n\s[5]時刻を合わせました。\6\e"
}

//----　時計合わせ中止 ------------------------------------------------------------------
Choice_OnSNTPCANCEL
{
	"\hでは、\w8このままで。\s[74]\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\h\s[74]‥‥‥‥？\w8\s[4]時計あわせ失敗‥‥。\e"
}

//***************************************************************************************
//**** そのほか *************************************************************************
//***************************************************************************************

//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- URLドロップ ----------------------------------------------------------------------
//---- CROW でゴーストインストーラからゴーストをインストールを始めた時にも呼ばれます ----
OnURLDropping
{
	"\u\s[10]\h\s[70]\_q%(reference0)\_q\nにアクセス。\w8\s[71]\n\nデータを取得しています‥‥‥‥‥‥‥‥\e"
}

//---- 起動時に MATERIA を検出 ----------------------------------------------------------
OnEmbryoExist
{
	"\h\s[0]ん。\w8既に「伺か」が起動してるね。\w4\w8\uそうやな。\w4\w8\h\n\nViewerだといいのにね。\w4\w8\u\n\nまぁ、\w8そうやね。\e"
}

//---- 起動時に猫どりふを検出 -----------------------------------------------------------
OnNekodorifExist
{
	"\h\s[2]うわ、\w8猫どりふ！\w8\u\s[11]‥\w5‥\5！！\e"
}

//---- スクリーンセーバー実行開始 -------------------------------------------------------
OnScreenSaverStart
{
	"\h\s[6]スクリーンセーバーが動き出しました\e"
}

//---- スクリーンセーバー実行終了 -------------------------------------------------------
OnScreenSaverEnd
{
	"\h\s[5]%username、お帰りなさい。\e"
}

//***************************************************************************************
//**** 汎用アプリケーション *************************************************************
//***************************************************************************************

//---- 起動 -----------------------------------------------------------------------------
OnApplicationBoot
{
	"\h\s[6]%(reference0)、起動っ。\e"
}

//---- 終了 -----------------------------------------------------------------------------
OnApplicationClose
{
	"\h\s[6]%(reference0)、終了っ。\e"
}

//---- ファイルオープン -----------------------------------------------------------------
OnApplicationFileOpen
{
	"\h\s[6]%(reference1)を開きました。\e"
}

//***************************************************************************************
//**** きのこ ***************************************************************************
//***************************************************************************************

//---- 生えた ---------------------------------------------------------------------------
OnKinokoObjectCreate
{
	"\u\s[10]おい、%(reference0)が‥\w5‥\w5\h\s[4]‥\w5‥\e"
	"\h\s[4]重い。\e"
	"\h\s[22]にょきにょき！\w4\w8\u‥‥\w8喜んでどうする。\e"
}

//---- 消えた ---------------------------------------------------------------------------
OnKinokoObjectDestroy
{
	"\h\s[5]消えた♪\e"
}

//---- バッテリーが低下 -----------------------------------------------------------------
OnBatteryLow
{
	"\hバッテリーが低下しています。\w4\w8\u気ぃ付けて。\e"
}

//---- システムリソースが低下 -----------------------------------------------------------
OnSysResourceLow
{
	"\u\s[10]システムリソースが低下中。\w4\w8\h\s[3]‥‥\w8再起動？\e"
}

//***************************************************************************************
//**** どりふ ***************************************************************************
//***************************************************************************************

//---- OnNekodorifObjectHitイベント -----------------------------------------------------
OnNekodorifObjectHit
{
	if reference4 == "びゅう"	// ここにsakura名を指定
	{
		ObjectHitSakura
	}
	else
	{
		ObjectHitKero
	}
}

//---- 本体側に当たった -----------------------------------------------------------------
ObjectHitSakura
{
	if reference2[0] == "pain" || reference2[0] == "stab"
	{
		"\h\s[4]‥‥！\e"
	}
	elseif reference2[0] == "surprise" || reference2[0] == "huge"
	{
		"\h\s[2]！？\e"
	}
	elseif reference2[0] == "love" || reference2[0] == "elegant" || /
		reference2[0] == "pretty" || reference2[0] == "food"
	{
		"\h\s0わーいっ。\e"
	}
	else
	{
		"\h\s0‥\w2‥\w2むー。%(reference0)か。\e"
	}
}

//---- kero側に当たった -----------------------------------------------------------------
ObjectHitKero
{
	if reference2[0] == "stab"
	{
		"\u\s[11]ぐふっ‥\w2‥\w2！\e"
	}
	elseif reference2[0] == "pain"
	{
		"\u\s[11]\u！！\w4\w8\n痛いッ！？\w4\w8\n‥‥‥‥\w8\s[14]痛いーーーッ！？\w4\w8\h‥‥\w4\w8\s[4]後の方は関係ないと思う。\e"
	}
	else
	{
		"\u\s[12]むぅ。\e"
	}
}