///////// 文　ゴーストテンプレート
///////// 種々のイベント辞書
///////// written by umeici.

//**** インストール関連 *****************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	<<"
	ぽ０５「インストールを開始するで〜。
	">>
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	"\0\s[0]"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"「%(reference[1])」、をインストールしたで。"
	--
	if reference[0] == "ghost" {
		if reference[1] == "" {
			"\nく　\w9ふ　\w9ふ　\w9ふ　\w9…。\w9\w9\1\s[10]…\w5…\w5変な笑い方すんなや。"
		}
	}
}


//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	<<"
	ぽ０３「インストールに失敗したで。
	え１０「原因は「%(SHIORI3FW.HTTPCodeToMessage(reference[0]))」みたいやね。
	">>
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	<<"
	ぽ０４「これは『%(reference[0])』さん専用やて。
	え１０「ゴーストを切り換えてからそちらに渡したってな。
	">>
}


//**** 消滅関連 *************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	<<"
	ぽ００「「はい」やと消えるで。「いいえ」やとやめるわ。
	">>
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	if ghostupmin_total() < 60 {
		<<"
		ぽ０３「いきなり消すことないやん〜。
		え１０「…。
		">>
	}
	else {
		<<"
		ぽ０８「さよならや〜。
		え１０「また会えたらええな。
		">>
	}
}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	<<"
	ぽ０６「やめるんやね。
	え１０「助かったやん。
	">>
}

OnVanishButtonHold
{
	<<"
	ぽ００「あれ、やめるんやね。
	え１０「消えずに済んだやん。
	">>
}


//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	<<"
	ぽ０６「%(reference[0])が消えたで。
	え１０「……。
	">>
}


//**** メールチェック *******************************************************************

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	<<"
	ぽ００「\_q%(reference[2])\_qのメールチェック中や。
	">>
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\0\s[0]\_q%(reference[2])\_q\nメールは無かったで。"
	}
	else
	{
		//---- メールが届いていた
		"\0\s[0]\_q%(reference[2])\n%(reference[0])通／%(reference[1])バイト\_q\nメールが届いてるで。\n\n[half]\_q"
		--
		メニュー('メーラーを開く','OpenMailer') + '\n'
		--
		メニュー('なにもしない','CloseMail') + '\n[half]\n'
	}
}

OpenMailer
{
	"\0\![open,mailer]"
}

CloseMail
{
	"\0\b[-1]\1\b[-1]"
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	<<"
	ぽ０４「メールチェック失敗。
	">>
	--
	if reference0 == "timeout"
	{
		//---- タイムアウト
		<<"
		
		え１０「メールサーバが応答してくれへんかった。
		え　　「サーバの設定が違うか、それとも混んでるんかな？
		">>
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		<<"
		
		ぽ０３「ＩＤかパスワードが違うんちゃうかな。
		">>
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		<<"
		というか……
		え１０「設定してへんのちゃう？
		">>
	}
	else
	{
		//---- 原因不明
		<<"
		原因は『%(reference[0])』やそうやけどな……。
		え１０「知らんわ。
		">>
	}
}


//**** ネットワーク更新 *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	<<"
	ぽ００「更新情報を取得中や〜。
	">>
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
	<<"
	ぽ０５「%(reference[0])個のファイルが更新されてるみたいやね。
	">>
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		<<"
		ぽ００「更新されてへんがな〜。
		">>
	}
	else
	{
		//---- 実際に更新が完了した
		<<"
		ぽ０５「ネットワーク更新終了や〜。
		え１０「ほぅか。
		">>
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference[0] == 'timeout' {
		<<"
		ぽ０４「時間切れやん。
		">>
	}
	elseif reference[0] == 'md5 miss' {
		<<"
		ぽ０３「データがおかしいみたいやで。
		え１０「どうしようもないんやけどな。
		">>
	}
	elseif reference[0] == '404' {
		<<"
		ぽ０４「更新用ファイルがないねん。
		え１１「困ったもんやな。
		">>
	}
	elseif reference[0] == 'artificial' {
		<<"
		ぽ０６「やんぴ。
		え１０「ちゃんと最後までせぇよ。
		">>
	}
	else {
		<<"
		ぽ０３「失敗ー。%(reference[0])やて。
		">>
	}
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	<<"
	ぽ００「\_q%(reference[0])をダウンロード中〜。\_q
	">>
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	<<"
	ぽ０６「\_q%(reference[0])を確認するわ。\_q
	">>
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	<<"
	ぽ００「『\_q　%(reference[1])\_q』
	待ち無しぽ００「『\_q　%(reference[2])\_q』
	待ち無しぽ０５「一緒〜。
	">>
}

//---- ネットワーク更新 MD5値不一致 -----------------------------------------------------
OnUpdate.OnMD5CompareFailure
{
	<<"
	ぽ００「『\_q　%(reference[1])\_q』
	待ち無しぽ００「『\_q　%(reference[2])\_q』
	待ち無しぽ０４「違ってるで〜。
	">>
}

//**** ヘッドラインセンス ***************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\0\s[0]「%(reference[0])」のヘッドラインを取得中や。\e"
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	"\0\s[0]\b[2]"
	--
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		//---- 最初のページ
		"「%(reference[0])」ヘッドラインやで。"
	}
	elseif reference2 == "Next"
	{
		//---- 真ん中あたりのページ
		"「%(reference[0])」の続きや。"
	}
	elseif reference2 == "Last"
	{
		//---- 最後のページ
		"「%(reference[0])」の最後のページや。"
	}
	--
	//---- ヘッドライン本体
	"\n\n%reference3\n\n"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		メニュー('次のページ','') + '\n'
		--
		メニュー('サイトを開く',reference[1]) + '\n'
		--
		メニュー('やめ','HEADLINECANCEL')
	}
	else
	{
		//---- 次のページがない場合
		メニュー('サイトを開く',reference[1]) + '\n'
		--
		メニュー('やめ','HEADLINECANCEL')
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	<<"
	ぽ００「更新されてへんかったわ。
	">>
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	if reference0 == "can't download"
	{
		<<"
		ぽ００「ヘッドラインセンス失敗。
		ぽ　　「ダウンロードでけへんかったわ。
		ぽ　　「あんまりにも重すぎるか、まずネットに繋がってへんか。
		">>
	}
	elseif reference0 == "can't analyze"
	{
		<<"
		ぽ００「ヘッドラインセンス失敗。
		ぽ　　「……解析失敗。
		ぽ　　「サイトのデザインが変更されたんちゃう〜？　
		ぽ　　「最新版のヘッドラインセンサがあれば入れ替えてや。
		">>
	}
	else
	{
		<<"
		ぽ００「ヘッドラインセンス失敗。
		ぽ　　「理由は%(reference[0])やて。
		">>
	}
}


//**** ファイル作成関連 *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	<<"
	ぽ００「更新用ファイルを作成するで。
	">>
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	<<"
	ぽ０６「終わりや。
	">>
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	<<"
	ぽ００「なーファイルを作成するで。
	">>
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	<<"
	ぽ００「なーファイルができたで。
	">>
}

//****　時計合わせ　*********************************************************************

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	<<"
	ぽ００「%(reference[0])で時計合わせするわ〜。
	">>
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
SNTPCompare_StrForm
{
	_txt = SPLIT(_argv[0],',')
	STRFORM("$04d/$02d/$02d $02d:$02d:$02d",TOINT(_txt[0]),TOINT(_txt[1]),TOINT(_txt[2]),TOINT(_txt[3]),TOINT(_txt[4]),TOINT(_txt[5]))
}

OnSNTPCompare
{
	"\h\s[6]\6\_q/
	あっち %(SNTPCompare_StrForm(reference[1]))\n/
	こっち %(SNTPCompare_StrForm(reference[2]))\n/
	\n\n[half]\_q\w9\w9"
	--
	if reference[3] == 0 {
		"\h\s[0]ずれてないやん。\w9\w9\u\s[10]ぴったりやで。\e"
	}
	else {
		"\h\s[5]\6%(reference[3])秒ずれとったんで、直しといたで〜。"
	}
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\u\s[10]\0\s[4]時計合わせ失敗や。\e"
}


//**** そのほか *************************************************************************

//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference[0]
	displaywidth  = reference[1]
	displayheight = reference[2]
}

OnNetworkHeavy
{
	<<"
	ぽ０３「……遅いやーん。
	">>
	
	<<"
	ぽ０３「混んでるってや。
	">>
}

OnURLDropping
{
	<<"
	ぽ００「\_q%(reference[0])\_qからダウンロード中や。
	">>
}

OnURLDropped
{
	<<"
	ぽ００「ダウンロードが終ったで。
	ぽ　　「ファイルは\_q%(reference[0])\_qにあるで〜。
	">>
}

OnWallpaperChange
{
	<<"
	ぽ００「壁紙を変更するで〜。
	">>
}

OnMusicPlay
{
	<<"
	ぽ０５「『%(reference[0])』再生開始〜
	">>
}

OnSSTPBreak
{
	<<"
	ぽ０２「……はっ！？
	">>
}