///////// 文　ゴーストテンプレート
///////// 文字列リソース辞書
///////// written by umeici.

//**** 文字列リソース *******************************************************************

//---- ユーザー名 -----------------------------------------------------------------------
On_username
{
	username
}

//---- ネットワーク更新の基準位置となるURL ----------------------------------------------
On_homeurl
{
	"http://ms.shillest.net/housekeeper/zz_other/miku/"
}

LinkMenuConvert
{
    _text = ''
    _data = IARRAY
    for _i = 0 ; _i < _argc ; _i++ {
        _data = (RE_SPLIT(_argv[_i],'[ \t]*\|[ \t]*'),'','') //ダミー
        _text += "%(_data[0])%(CHR(1))%(_data[1])%(CHR(1))%(_data[2])%(CHR(1))%(CHR(2))"
    }
    _text;
}

//---- ポータルサイトのボタンキャプション -----------------------------------------------
On_portalrootbutton.caption
{
	"おすすめ。(&P)"
}

//---- ポータルサイトのリスト -----------------------------------------------------------
On_sakura.portalsites
{
	LinkMenuConvert(On_sakura.portalsites_EX)
}

On_sakura.portalsites_EX : array
{
	'C.R.O.W. official page		 | http://crow.aqrs.jp/							 | n'
	'SSP BUGTRAQ				 | http://ssp.shillest.net/						 | bug'
	'うさださくら				 | http://usada.sakura.vg/						 | n'
	'-|-|-'
	'Yet Another AYA			 | http://code.google.com/p/yaya-shiori/		 | n'
	'文Wiki「文屋」				 | http://emily.shillest.net/ayaya/				 | n'
	'-|-|-'
	'極秘生産拠点「ぐんにょり」	 | http://k-a2shi.hp.infoseek.co.jp/ukagaka/	 | n'
}

//---- 本体側おすすめサイトのボタンキャプション -----------------------------------------
On_recommendrootbutton.caption
{
	"いろいろ(&R)"
	"お気に入り(&R)"
}

//---- 本体側おすすめサイトのリスト -----------------------------------------------------
On_sakura.recommendsites
{
	LinkMenuConvert(On_sakura.recommendsites_EX)
}

On_sakura.recommendsites_EX : array
{
	'TinyPalace					 | http://www.towano.net/							 | tinybana'
	'-|-|-'
	'SSTP BOTTLE				 | http://bottle.mikage.to/							 | bottle'
	'伺か 統合Link				 | http://www.towano.net/nisesakura/index2.html		 | niseharuna'
	'-|-|-'
	'Marble Note				 | http://marble.tarenari.jp/						 | marble'
	'何かゴーストセンター		 | http://ngc.aqrs.jp/								 | ngc'
	'GHOST TOWN					 | http://ghost.sakura.vg/							 | bannertown'
	'噂と評判[改]				 | http://review.sakura.ne.jp/						 | uwahyo'
}

//---- kero側おすすめサイトのボタンキャプション -----------------------------------------
On_kero.recommendbuttoncaption
{
	"お気に入り(&R)"
	"おすすめ(&R)"
}

//---- kero側おすすめサイトのリスト -----------------------------------------------------
On_kero.recommendsites
{
	LinkMenuConvert(On_kero.recommendsites_EX)
}

On_kero.recommendsites_EX : array
{
	'本丸						 | http://fa-x.hp.infoseek.co.jp/					 | -'
	'二の丸						 | http://ms.shillest.net/							 | -'
}

//---- ネットワーク更新ボタンのキャプション ---------------------------------------------
On_updatebutton.caption
{
	"進化できるかもしれない。(&U)"
	"明日があるさ(&U)"
	"%(mv)を拾いますか？(&U)"
	"頭が良くなるボタン(&U)"
}

//---- readmeボタンのキャプション -------------------------------------------------------
On_readmebutton.caption
{
	"りいどみぃ"
}

//---- 消滅指示ボタンのキャプション -----------------------------------------------------
On_vanishbutton.caption
{
	"ボッシュート"
}

//---- 消滅指示ボタン表示切り替え -------------------------------------------------------
On_vanishbutton.visible
{
	//---- "0"で非表示、それ以外で表示
	"1"
}

//---- 起動中の他のゴースト名取得 -------------------------------------------------------
On_otherghostname
{
	// 現在起動中のゴーストのリストを作成する
	ghostexlist = IARRAY
	_n = ARRAYSIZE(reference)
	for _i = 0 ; _i < _n ; _i++ {
		ghostexlist ,= SPLIT(reference[_i],CHR(1))[0]
	}
}

//---- SHIORI 関連情報 ------------------------------------------------------------------
On_version
{
	GETSETTING(AYAINFO_VERSION)
}

On_craftman
{
	"umeici"
}

On_craftmanw
{
	"梅市"
}

On_name
{
	"AYA"
}

//---- Owned SSTP 用 uniqueid 取得 ------------------------------------------------------
On_uniqueid
{
	uniqueid = reference0
}

//---- hwnd 取得 ------------------------------------------------------------------------
On_hwnd
{
	sakurahwnd    = reference0[0]
	kerohwnd      = reference0[1]
	sakurablnhwnd = reference1[0]
	keroblnhwnd   = reference1[1]
}