///////// 文　ゴーストテンプレート
///////// 種々のイベント辞書
///////// written by umeici.

//**** インストール関連 *****************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	"\h\s[0]あれ？\w5\s[5]何か来ましたよ。\w9\w5\u\s[10]使えるようにしろっちゅーことやね。\w9\w9\e"
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	if reference0 == "shell"
	{
		"\h\s[5]着替えが届いたようです。\w9\w5\u\s[10]早速着てみたらどうや？\e"
	}
	elseif reference0 == "ghost"
	{
		if reference1 == '美紅' {
			"\h\s[3]再インストール\w5‥\w5‥\w5ですか？\e"
		}
		else {
			"\h\s[5]%(reference1)さんが来られたようですよ。\w9\w9\u\s[10]どうやらそのようやな。\w9\w9\h\n\nさっそく呼んでみますか？\_q\n\n"
			--
			if basewarenameex != 'embryo' && basewarenameex != 'crow' {
				"\![*]\q[%(MItem('呼んでみる')),InstallCall]\n"
			}
			--
			"\![*]\q[%(MItem('交代してみる')),InstallChange]\n"
			--
			"\n[half]\![*]\q[%(MItem('なにもしない')),Cancel2]\_q"
		}
	}
	elseif reference0 == "plugin"
	{
		"\h\s[5]プラグイン「%(reference1)」が届きました。\e"
	}
	elseif reference0 == "headline"
	{
		"\h\s[50]ヘッドラインセンサー「%(reference1)」が追加されました。\w9\w9\s[5]\nこれであなたも情報通っ♪\w9\w9\u\s[10]なんやそれ。\e"
	}
	elseif reference0 == "rss"
	{
		"\h\s[50]RSS「%(reference1)」が追加されました。\w9\w9\s[5]\nこれであなたも情報通っ♪\w9\w9\u\s[10]なんやそれ。\e"
	}
	elseif reference0 == "supplement"
	{
		"\h\s[50]差分ファイル「%(reference1)」、\w5インストール終了です。\e"
	}
	else {
		"\h\s[5]「%(reference1)」をインストールしました。\e"
	}
}

Select.InstallChange
{
	"\![change,ghost,lastinstalled]"
}

Select.InstallCall
{
	"\![call,ghost,lastinstalled]"
}

//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	"\h\s[3]失敗してしまいました。\e"
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	"\h\s[6]‥\w5‥\s[0]宛先が違いますね。\w9\n郵便事故でしょうか。\w9\w5\u\s[10]%(reference0)宛てになっとるで。\w9\nねここが間違えたんか？\w9\w9\h\s[4]\n\nねここさんって運送業務してたんですか？\e"
}


//**** 消滅関連 *************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	"\h\s[3]‥\w5‥。\u\s[10]‥\w5‥。\w9\e"
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	"\h\s[0]そうですか\w5‥\w5‥。\w9\nついにこのときが来たんですね。\w9\w5\u新しい宿を探さなあかんのか。\w9\w9\h\s[5]\n\nそんなこと言わずに、\w5またここに戻ってこられるのを願っていましょうよ。\w9\w5\u\n\n‥\w5‥\w5そやね。\w9\nそこまで居心地、悪なかったしな。\w9\w9\h\s[0]\n\nそれじゃあ、\w5\s[5]またいつか。\w9\w5\u\n\n今までありがとな。\w9\n\e"
}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	"\h\s[6]‥\w5‥\w5♪\w9\s[5]\w9\w9\u‥\w5‥\w5♪\s[1100]\w9\e"
}
OnVanishButtonHold
{
	"\u\s[10]\h\s[2]え？\w9\w9‥\w5‥\w9\w[50]♪\e"
}

//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	SetShellName(reference7)
	"\u\s[10]\h\s[3]%(reference0)さんの「気」が消えた\w5‥\w5‥。\w9\w9\u今更ドラゴンボールネタかい。\e"
}


//**** メールチェック *******************************************************************

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	"\h\s[50]メールサーバに接続します。\e"
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\h\s[3]特にメールはないみたいですね。\w9\w9\u\s[10]骨折り損かい。\e"
	}
	else
	{
		//---- メールが届いていた
		"\h\s[0]メールがあるみたいですよ？\w9\w9\n\nえっと、\w9%(reference0)通来てますね。\w9\w9\n\nメーラーを起動しましょうか？\n\n\w5\![*]\q[%(MItem('起動する')),Open_mail]\n\![*]\q[%(MItem('やめとく')),Cancel]"
	}
}

Select.Open_mail
{
	"\h\s[0]では、\w5起動します。\w9\w5\![open,mailer]\e"
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウト
		"\h\s[4]繋がりませんね\w5‥\w5‥。\w9\w9ちゃんとネットに繋いでますか？\e"
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		"\h\s[4]蹴られちゃいました。\e"
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		"\h\s[3]‥\w5‥\w5ちゃんとメール設定できてますか？\e"
	}
	else
	{
		//---- 原因不明
		"\h\s[4]%(reference0)エラーです。\w9\w9\u\s[10]\n\n何やこのエラー？\e"
	}
}


//**** ネットワーク更新 *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	"\h\s[5]参考書を取り寄せています。\w9\w5\u‥\w5‥\w5参考書？\e"
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
	"\h\s[0]%(TOINT(reference0)+1)冊の参考書を取り寄せました。\e"
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\h\s[4]えと、\w5新刊が入ってなかったです。\e"
		"\u\s[10]なんも無かったな。\w9\w5\h\s[4]ごめんなさい。\e"
		"\h\s[4]‥\w5‥。\w9\w9\u\s[10]元気出せや。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\h\s[6]‥\w5‥\s[5]これでまた知識が増えましたね。\w9\w5\uそれはどうやろな。\w9\w5\h\s[2]\n\nええ！？\e"
		"\h\s[5]進化しました。\w8\w6\u‥\w5‥\w5進化？\e"
		"\h\s[6]延命治療成功。\w9\w5\u\s[10]言うてはならんことを…。\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\h\s[4]な\w9\nん\w9\nだ\w9\nか\w9\nか\w9\nら\w9\nだ\w9\nが\w9\nお\w9\nも\w9\nい\w9\nで\w9\nす\w9\n。\u無駄なことすなや。\e"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\h\s[0]えーっと\w5‥\w5‥。\e"
	}
	elseif reference0 == "404" || reference0 == "403"
	{
		"\h\s[4]%(reference0)\w5‥\w5‥。\w9\w9\u\s[10]まずいのう。\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\h\s[2]あっ\w5‥\w5‥\s[3]\w9え‥\w5‥\w5と。\w9\w5\uどないしたんや？\w9\w9\h\s[4]\n\n‥\w5‥\w5混乱してしまいました。\w9\w9\u\n\n‥\w5‥\w5馬鹿者やね。\w5\h\n\n‥\w5‥。\u能無しやね。\w9\h\s[7]\n\nそこまで言うことないじゃないですか！！\e"
	}
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	"\0\s[0]参考書「%(reference0)」をダウンロードします。\e"
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	"\h\s[0]暗号を照らし合わせています。\u\s[10]\w9‥\w5‥\w5暗号？\e"
	"\h\s[600]ふむふむ\w5‥\w5‥。\e"
	"\h\s[5]さぁ、\w5来ましたよー。\e"
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	"\h\s[0]一致しました。\e"
}

//---- ネットワーク更新 MD5値不一致 -----------------------------------------------------
OnUpdate.OnMD5CompareFailure
{
	"\h\s[0]えーっと\w5‥\w5‥。\e"
}

//**** ヘッドラインセンス ***************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\h\s[6]\w3%(reference0)から情報を仕入れてきます。\e"
}

OnRSSBegin
{
	OnHeadlinesenseBegin
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		"\h\b[2]\s[50]サイト%(reference0) です。"
	}
	else
	{
		"\h\b[2]\s[0]%(reference0) の続きです。"
	}
	--
	//---- ヘッドライン本体
	"\n\n%reference3\n\n"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		"\q[%(MItem('次のページ')),]\n/
		\q[%(MItem('サイトへ')),%(reference1)]\n/
		\q[%(MItem('やめ')),HEADLINECANCEL]\e"
	}
	else
	{
		//---- 次のページがない場合
		"\h\s[6]\w6おしまい。\w9どうします？\n"
		--
		"\q[%(MItem('サイトへ')),%(reference1)]\n/
		\q[%(MItem('やめ')),HEADLINECANCEL]\e"
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\h\s[0]前回からの更新はありませんでした。\e"
}

OnRSSComplete
{
	_n = ARRAYSIZE(reference)
	if _n <= 2 {
		OnHeadlinesenseComplete
	}
	else {
		"\h\b[2]\s[5]%(reference0)のRSSです。\_q\n\n[half]"
		--
		_text = ''
		for _i = 2 ; _i < _n ; _i++ {
			_array = SPLIT(reference[_i],CHR(1))
			if RE_SEARCH(_array[0],'^AD:') || RE_SEARCH(_array[0],'\[ *PR *\]') {
				continue
			}
			
			_text += "\![*]\_a[%(_array[1])]"
			
			if ( STRLEN(_array[2]) ) {
				_date = SPLIT(_array[2],',')
				_array[0] = STRFORM("[$02d/$02d]",TOINT(_date[1]),TOINT(_date[2])) + _array[0]
			}
			
			_text += _array[0]
			
			_text += "\_a\n"
		}
		_text
		--
		"\n[half]"
		--
		"\q[%(MItem('サイトへ')),%(reference1)]\n/
		\q[%(MItem('やめ')),HEADLINECANCEL]\e"
	}
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	if reference0 == "can't download"
	{
		"\h\s[4]ダウンロードに失敗してしまいました。"
	}
	elseif reference0 == "can't analyze"
	{
		"\h\s[4]解析に失敗してしまいました。"
	}
	else
	{
		"\h\s[4]失敗してしまいました。"
	}
	--
	"\w9\w5\uワイのせいや無いで。\w9\w9\h\n\n‥\w5‥\w5本当に？\w9\u\s[11]\n\n！！\e"
}

OnRSSFailure
{
	OnHeadlinesenseFailure
}

//**** ファイル作成関連 *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\h\s[0]updates2.dau の作成を開始します。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\h\s[5]作成終了しました。\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\h\s[0]それでは、%(reference0)の圧縮ファイルを作ります。\w3\n"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\h\s[5]\w4%(reference0)の圧縮ファイル、\n\w4\_!%(reference1)\_!作成完了しました。"
}

//****　時計合わせ　*********************************************************************

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\h\s[0]ＳＮＴＰサーバ\n\n%(reference0)\n\nに接続します。\w9\w5\u秒単位のズレ直してどうするんやろな。\w9\w5\h\s[4]\n\nあまり暴言を吐かないでくださいよ。\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
SNTPCompare_StrForm
{
	_txt = _argv[0]
	SETDELIM(_txt,",")
	STRFORM("$04d/$02d/$02d $02d:$02d:$02d",TOINT(_txt[0]),TOINT(_txt[1]),TOINT(_txt[2]),TOINT(_txt[3]),TOINT(_txt[4]),TOINT(_txt[5]))
}

OnSNTPCompare
{
	"\1\s[10]\_q/
	サーバ時刻　：%(SNTPCompare_StrForm(reference1))\n/
	ローカル時刻：%(SNTPCompare_StrForm(reference2))\n/
	\n\n[half]\_q\w9\w9"
	--
	if reference3 == 0
	{
		"\u直す必要は無いみたいやで。\w9\w5\h\s[5]ぴったりですね。\e"
	}
	else
	{
		if reference3 < 10 {
			"\h\s[0]%(reference3)秒ずれてるようですね。"
		}
		else {
			"\h\s[4]かなりずれてますね。"
		}
		--
		"\n\h\s[0]直しますか？\n\n\![*]\q[%(MItem('はい')),Adjust]\n\![*]\q[%(MItem('ほっとく')),NoAdjust]\e"
	}
}

Select.Adjust
{
	"\h\s[5] 直しました。\6\e"
}

Select.NoAdjust
{
	"\h\s[3]そうですか。\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\h\s[4]失敗してしまいました。\w9\w5\uワイのせいや無いで。\w9\w9\h\n\n‥\w5‥\w5本当に？\w9\u\s[11]\n\n！！\e"
}


//**** そのほか *************************************************************************

//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- URLドロップ ----------------------------------------------------------------------
//---- CROW でゴーストインストーラからゴーストをインストールを始めた時にも呼ばれます ----
OnURLDropping
{
	"\h\s[50]\w3%(reference0)からダウンロードを開始します。\n\w4\e"
}

OnURLDropped
{
	"\h\s[6]\w4ファイルを%(reference0)に収納しました。\n\w4\e"
}

OnURLDropFailure
{
	if reference0 == 'artificial' {
		"\h\s[6]ダウンロードを中断しました。\e"
	}
	else {
		"\h\s[4]ダウンロードに失敗しました。\e"
	}
}

//--------------------------------------------------------------------------

OnSSTPBreak
{
	"\h\s[50]毒電波を遮断しました。\w9\w9\u\s[11]！？\e"
}