///////// 文　ゴーストテンプレート
///////// マウス入力関連辞書
///////// copyright (C) 2002-2003 umeici.

//**** 撫で反応 *************************************************************************

//---- OnMouseMoveイベント --------------------------------------------------------------
OnMouseMove
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側の撫で
		MouseMoveSakura
	}
	else
	{
		//---- kero側の撫で
		MouseMoveKero
	}
}

//---- 本体側の撫で反応 -----------------------------------------------------------------
MouseMoveSakura
{
	if reference4 != ""
	{
		//----どこかが撫でられている
		stroke++
		//---- 撫でられた量が一定量に達したら「なでられている」と判断
		if stroke >= 64
		{
			//---- 撫でられた。撫でられた部位を見てトークする
			if reference4 == "Head"
			{
				ChoiceHead
			}
			elseif reference4 == "Bust"
			{
				ChoiceBust
			}
			elseif reference4 == "Skirt"
			{
				ChoiceSkirt
			}
			elseif reference4 == "Head2"
			{
				ChoiceHead
			}
			stroke = 0
		}
	}
	else
	{
		// 定義された部位はどこも撫でられていない
		stroke = 0
	}
}

//---- kero側の撫で反応 -----------------------------------------------------------------
MouseMoveKero
{
	//---- なし
}


//**** つつかれ反応 *********************************************************************

//---- OnMouseDoubleClickイベント -------------------------------------------------------
OnMouseDoubleClick
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側のつつかれ
		MouseDoubleClickSakura
	}
	else
	{
		//---- kero側のつつかれ
		MouseDoubleClickKero
	}
}

//---- 本体側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickSakura
{
	//---- 顔つつかれ処理
	if reference4 == "Face"
	{
		//---- メニュー展開
		OpenMenu
	}
	elseif reference4 == "Head"
	{
		ChoiceHead
	}
	elseif reference4 == "Bust"
	{
		ChoiceBust
	}
	elseif reference4 == "Skirt"
	{
		ChoiceSkirt
	}
	elseif reference4 == "Head2"
	{
		OpenMenu
	}
	else
	{
		OnAiTalk
	}
}

//---- 反応まとめ -------------------------------------------------------------
ChoiceHead : nonoverlap
{
	"\0\s[1]・・・\e"
	"\0\s[5]・・・\e"
}


ChoiceBust : nonoverlap
{
	"\0\s[2]？？？\e"
	"\0\s[3]・・・だ、誰？\e"
	"\0\s[4]・・・\e"
}

ChoiceSkirt
{
	EVAL("ChoiceSkirt%floatingmode")
}

ChoiceSkirt0 : nonoverlap
{
	"\0\s[30]\w9\s[31]・・・\e"
	"\0\s[30]\w9\s[31]・・・！\e"
	"\0\s[30]\w9\s[31]・・・だ、誰？\e"
}

ChoiceSkirt1 : nonoverlap
{
	"\0\s[7]・・・\e"
	"\0\s[7]・・・！\e"
	"\0\s[7]・・・だ、誰？\e"
}

//---- kero側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickKero
{
}