///////// 文　ゴーストテンプレート
///////// メニュー処理辞書
///////// copyright (C) 2002 umeici.

//**** メインメニューの展開 *************************************************************

//---- メインメニュー展開 ---------------------------------------------------------------
OpenMenu
{
	"\s[0]はい、何ですか？"
	"\s[5]どうしました？"
	--
	OpenMenuCore
}

OpenMenuReturn
{
	"\h\s[5]戻りました。"
	--
	OpenMenuCore
}

OpenMenuCore
{
	"\_q\n\n/
	\![*]\q[%(MENUITEM('なにか話して')),OnAiTalk]\n"
	--
	if LastTalk != "" {
		"\![*]\q[%(MENUITEM('さっきの話を聞きたい')),OnLastTalk]\n"
	}
	--
	"\![*]\q[%(MENUITEM('しゃべり頻度を変えて')),ChoiceTalkInterval]\n/
	\![*]\q[%(MENUITEM('お仕事')),Choiceworks]\n\n[half]/
	\![*]\q[%(MENUITEM('なんでもない')),ChoiceCancel]\_q\e"
}

//---- メニュー項目の後ろにスペースを補完する関数
MENUITEM
{
	_menuitem = _argv[0]
	for _i = GETSTRBYTES(_menuitem) ; _i < 48 ; _i++
	{
		_menuitem += " "
	}
	_menuitem
}

//**** メニュー項目選択 *****************************************************************

//---- その他のメニュー ---------------------------------------------------------
MenuFooter
{
	"\n[half]/
	\![*]\q[%(MENUITEM('メインメニューに戻る')),OpenMenuReturn]\n/
	\![*]\q[%(MENUITEM('なんでもない')),ChoiceCancel]\_q\e"
}


//---- トーク頻度の調整
ChoiceTalkInterval
{
	"\0\s[0]どのくらいがいいのかな？\_q\n\n/
	\![*]\q[%(MENUITEM('うるさいくらい')),ChoiceTalkMax]\n/
	\![*]\q[%(MENUITEM('ふつう')),ChoiceTalkNormal]\n/
	\![*]\q[%(MENUITEM('のんびり')),ChoiceTalkPoor]\n/
	\![*]\q[%(MENUITEM('黙ってて')),ChoiceTalkNone]\n"
	--
	MenuFooter
}

//---- トーク頻度
ChoiceTalkMax
{
	//---- うるさく話す(15秒間隔)
	aitalkinterval = 15
	"\0\s[5]じゃ、張り切っていきます。\e"
}

ChoiceTalkNormal
{
	//---- ふつうに話す(2分間隔)
	aitalkinterval = 120
	"\0\s[0]じゃ、普通に。\e"
}

ChoiceTalkPoor
{
	//---- のんびり話す(5分間隔)
	aitalkinterval = 300
	"\0\s[0]じゃ、のんびりと。\e"
}

ChoiceTalkNone
{
	//---- 話さない
	aitalkinterval = 0
	"\0\s[8]はい、静かにしてます。\e"
}

//---- 直前のトーク再現 -------------------------------------------------------------------------
OnLastTalk
{
	"\0\s[6]え？　\w5さっきの？\w9\w9\w9\c%LastTalk"
	"\0\s[0]えーっと\w5…\w5…\w5\w9\w9\w9\c%LastTalk"
}

//---- キャンセル ---------------------------------------------------------
ChoiceCancel
{
	"\0\s[8]え。\e"
	"\0\s[8]えー。\e"
}

//---- メニュー選択タイムアウト ---------------------------------------------------------
選択肢時間切れ
{
	"\0\s[8]ちゃんと選んでくださいっ！\e"
}