///////// 文　ゴーストテンプレート
///////// メニュー処理辞書
///////// copyright (C) 2002 umeici.

//**** メインメニューの展開 *************************************************************

//---- メインメニュー展開 ---------------------------------------------------------------
OpenMenu
{
	"\0\s[5]"
	--
	"はーい。"
	"どうしたの？"
	--
	"\n\n/
	\![*]\q[";--;MENUITEM("おはなしして");--;",OnAiTalk]\n"
	--
		if LastTalk != ""
		{
			"\![*]\q[";--;MENUITEM("さっきのおはなし");--;",OnLastTalk]\n"
		}
	--
	"\![*]\q[";--;MENUITEM("じかんがきたらおしえて");--;",ChoiceTimer]\n/
	\![*]\q[";--;MENUITEM("でたらめ☆てんきよほう");--;",WEATHER_REPORT]\n/
	\![*]\q[";--;MENUITEM("いっしょにあそんだじかん");--;",HANAYU]\n/
	\![*]\q[";--;MENUITEM("そのほか");--;",ChoiceModeetc]\n/
	\![*]\q[";--;MENUITEM("なんでもない");--;",CANCEL]\e"
}

ChoiceModeetc
{
	"\![*]\q[";--;MENUITEM("おしゃべりひんど");--;",TALKINTERVAL]\n/
	\![*]\q[";--;MENUITEM("たんじょうびをおぼえる");--;",BIRTHDAYENTRY]\n/
	\![*]\q[";--;MENUITEM("ごみ箱の片付け");--;",ChoiceGarbagecan]\n/
	\![*]\q[";--;MENUITEM("じゆういどうのせってい");--;",Free_movement]\n/
	\![*]\q[";--;MENUITEM("まえにもどる");--;",OpenMenu]\n\n[half]/
	\![*]\q[";--;MENUITEM("なんでもない");--;",ChoiceCancel]\e"
}

//---- メニュー項目の後ろにスペースを補完する関数
MENUITEM
{
	_menuitem = _argv[0]
	for _i = GETSTRBYTES(_menuitem) ; _i < 48 ; _i++
	{
		_menuitem += " "
	}
	_menuitem
}


//**** メニュー項目選択 *****************************************************************

//---- OnChoiceSelectイベント -----------------------------------------------------------
//OnChoiceSelectイベント関数は、全て頭にChoiceとつける（私が分かるように）
OnChoiceSelect
{
	EVAL(reference0)
}

TALKINTERVAL
{
	//---- トーク頻度の調整
	"\0\s[0]どのくらいがいい？\n\n/
	\q[";--;MENUITEM("うるさいくらい");--;",TALKMAX]\n/
	\q[";--;MENUITEM("ふつう");--;",TALKNORMAL]\n/
	\q[";--;MENUITEM("しずか");--;",TALKPOOR]\n/
	\q[";--;MENUITEM("だまって");--;",TALKNONE]\e"
}

CANCEL
{
	//---- キャンセルされた
	"\0\s[4]あうー。\e"
	"\0\s[2]むー。\e"
}

//---- トーク頻度
TALKMAX
{
	//---- うるさく話す(15秒間隔)
	aitalkinterval = 15
	"\0\s[5]よーし、はなしちゃうよーっ。\e"
}

TALKNORMAL
{
	//---- ふつうに話す(3分間隔)
	aitalkinterval = 180
	"\0\s[5]ふつうにね。\1\s[10]うん。\e"
}

TALKPOOR
{
	//---- 静かに話す(5分間隔)
	aitalkinterval = 300
	"\0\s[0]ひかえめ？\1\s[10]うむ。\e"
}

TALKNONE
{
	//---- 話さない
	aitalkinterval = 0
	"\0\s[3]・\w6・\w6・\w6ぐす・\w6・\w6・\w6。\1\s[10]仕方ないだろ。\e"
}

//---- 直前のトーク再現 -------------------------------------------------------------------------
OnLastTalk
{
	"\0\s[0]えっと、えっと・・・\w9\w9\w9\c/
	%LastTalk"
}

//---- 自由移動 ---------------------------------------------------------
Free_movement
{
	"\0\s[5]どうしますか？\n\n[half]/
	\![*]\q[";--;MENUITEM("じゆうにうごいて");--;",Free_movement_On]\n/
	\![*]\q[";--;MENUITEM("いちばんしたにいて");--;",Free_movement_Off]\e"
}

Free_movement_On
{
	movement = 1
	"\0\s[5]じゆうに、うごくよ。\0\1\_s\![set,alignmenttodesktop,free]\_s\e"
}

Free_movement_Off
{
	movement = 0
	"\0\s[5]いちばんしたに、いるよ。\0\1\_s\![set,alignmenttodesktop,bottom]\_s\e"
}

// 起動時用

movement_status
{
	EVAL("movement_status%movement")
}

movement_status0
{
	"\0\1\_s\![set,alignmenttodesktop,bottom]\_s"
}

movement_status1
{
	"\0\1\_s\![set,alignmenttodesktop,free]\_s"
}


//---- ヘッドライン---------------------------------------------------------

HEADLINECANCEL
{
	//---- キャンセルされた
	"\0\s[0]はーい。\e"
}


//---- 誕生日を覚える---------------------------------------------------------

BIRTHDAYENTRY
{
	"\0\s[5]おたんじょうび、おしえてー。\n\n\w8\1\s[10]YYYYMMDDとか、ＹＹＹＹ年ＭＭ月ＤＤ日とか、\nYYYY/MM/DDあたりで入力してくれ。\w8\0\s[5]おねがい。\![open,inputbox,OnInputBirthday,-1]\e"
}


//---- 一緒にいました時間 ---------------------------------------------------------
HANAYU
{
	"\1\s[10]一週間分の起動時間をグラフ表示します。\w8\w8\![raise,OnCallHanayu]\n\n閉じたいときは、\nグラフをダブルクリックしてください。\e"
}

//---- でたらめ天気予報ーーーーー
WEATHER_REPORT
{
	"\0\s[5]さて、ここで、あしたのおてんきです。\w5\n\n\w8\1\s[10]（デタラメだからな）\n\n\w8\w8\0んーと・・・・\w8\n%WEATHER"
}

WEATHER : nonoverlap
{
	"\s[1]おひるごろ、\nおっきなアメだまが、ふってくるでしょう。\w8\1\s[10]なんだそりゃ？\e"
	"\s[5]あめがいっぱいふって、みちが川みたいに\nなってるでしょう。\w8\1\s[10]（嬉しそうに言うなって）\e"
	"\s[5]ずっと、はれるでしょう。\w8\1\s[10]お、そうか。"
}


//---- メニュー選択タイムアウト ---------------------------------------------------------
OnChoiceTimeout
{
	"\0\s[7]ちゃんと、えらんで！\e"
}