///////// 文　ゴーストテンプレート
///////// 種々のイベント辞書
///////// copyright (C) 2002 umeici.

//**** インストール関連 *****************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	"\0\s[0]いんすとーるしています。\e"
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	"\0\s[0]"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"「%reference1」、いんすとーるしました。"
	--
	if reference0 == "ghost"
	{
		Ghostname = reference1
		"/
		\nこうたいする？\n\n/
		\![*]\q[";--;MENUITEM("よろしく");--;",ChoiceGhostchange0]\n/
		\![*]\q[";--;MENUITEM("いや、あとで");--;",ChoiceGhostchange1]\e"
	}
	else
	{
		"\e"
	}
}

//ゴースト交代可否
ChoiceGhostchange0
{
	"/
	\1\s[10]\cでは、%Ghostnameさんと交代します。\w5\n/
	たまにうまく行かない場合もあるので、\w5\n/
	そのときは手動で切り替えてください。\w8/
	\0\s[5]またねえ。\w9\w9/
	\![change,ghost,%Ghostname]\e"
}

ChoiceGhostchange1
{
	"\0\s[5]はーい。\e"
}

//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	"\1\s[10]インストール失敗。\n\n理由：%reference0。\0\s[4]あーあ。\e"
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	"\1\s[10]これは、%reference0用の\nアーカイブだ。\w6\0\s[4]すとっぷ。\e"
}


//**** 消滅関連 *************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	"\0\s[3]%selfnameのこと、きらいになったの？\e"
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	"\0\s[3]ぐすっ\w5・\w5・\w5・\w5・\w5\nばいばい。\w5/
	\1\s[10]また、どこかで会おう。\w9\w9\e"
}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	"\1\s[10]どうやら助かったぞ。\w5/
		\0\s[5]だれでも、まちがいってあるよね。\e"
}

//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	"\0\s[3]%reference0、かわいそう・・・\n\n\w5\1\s[10]俺たちの明日の姿かも知れんな。\w5\0\s[3]ぐすっ・・・\e"
}


//**** メールチェック *******************************************************************

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	"\0\s[0]おてがみ、きたかな？\n%keroname、よろしくね。\1\s[10]わかった。\e"
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\1\s[10]メールは無かったな。\w5\0\s[0]ごくろうさまー。\e"
	}
	else
	{
		//---- メールが届いていた
		"\1\s[10]%reference0通のメールがあったぞ。\w5\0\s[5]おてがみ、ありました。\e"
	}
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウト
		"\1\s[10]タイムアウト。\0\s[4]%username、たいむあうと、だって。\e"
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		"\1\s[10]蹴られたぞ。\0\s[4]%username、けられたって。\e"
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		"\1\s[10]ぜんぜんダメだ。\nメールチェックの設定を見なおしてくれ。\w5\0\s[4]ありゃー。\e"
	}
	else
	{
		//---- 原因不明
		"\1\s[10]原因はわからないが、失敗。\w5\0\s[4]ありゃー。\e"
	}
}


//**** ネットワーク更新 *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	if reference3 == "baseware"
	{
		"\0\s[25]ほんたいのねっとわーくこうしん、\nかいしします。\w5\1\s[10]何のことか理解してないな・・・\e"
	}
	else
	{
		"\0\s[25]ねっとわーくこうしん、かいしします。\w5\1\s[10]何のことか理解してないな・・・\e"
	}
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
GetSender = REQ.VALUE("Sender")
Getfiles = reference0+1
	{
		if Getfiles >= 10
		{
			"\0\s[3]%keroname、たくさんあるんだって。\n\n\w8\1\s[10]急いでやろうな。\w5\0\s[0]うん。\e"
		}
		else
		{
			if GetSender == "NiseRingo"
			{
				"\0\s[0]あたらしいのは\w3\n%reference0こ。\e"
			}
			else
			{
				"\0\s[0]あたらしいのは\w3\n%Getfilesこ。\e"
			}
		}
	}
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\1\s[10]更新は無し。\w5\0\s[4]にょあー。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\1\s[10]更新完了〜。\w5\0\s[5]やったー。%movement_status\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\1\s[10]タイムアウト。\0\s[4]%username、たいむあうと、だって。\e"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\1\s[10]MD5値が違ってましたぜ。\w5\0\s[4]にょあー。"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\1\s[10]%reference0、だって。\w5\0\s[4]うーん。"
	}
	--
	"\n\n\1\s[10]ネットワーク更新、失敗だ。\e"
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	if Getfiles >= 10
	{
		"\_q\0\s[0]「%reference0」を、だうんろーど、します。\_q\e"
	}
	else
	{
		"\0\s[0]「%reference0」を、だうんろーど、します。\e"
	}
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	if Getfiles >= 10
	{
		"\_q\0\s[0]ちぇっく、はじめます。\_q\e"
	}
	else
	{
		"\0\s[0]ちぇっく、はじめます。\e"
	}
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	if Getfiles >= 10
	{
		"\_q\0\s[5]おっけー。\_q\e"
	}
	else
	{
		"\0\s[5]おっけー。\e"
		"\0\s[5]あってるよ。\1\s[10]うむ。\w"
	}
}

//---- ネットワーク更新 MD5値不一致 -----------------------------------------------------
OnUpdate.OnMD5CompareFailure
{
	"\1\s[10]MD5不一致！\0\s[4]にょあー。\e"
}

//**** ヘッドラインセンス ***************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\0\s[0]%reference0ヘッドライン取得中。\e"
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		//---- 最初のページ
		"\0\b2\s[0]%reference0ヘッドライン、さいしょのページ。"
	}
	elseif reference2 == "Next"
	{
		//---- 真ん中あたりのページ
		"\0\b2\s[0]%reference0ヘッドライン、つづき。"
	}
	elseif reference2 == "Last"
	{
		//---- 最後のページ
		"\0\b2\s[0]%reference0ヘッドライン、これがさいごです。"
	}
	--
	//---- ヘッドライン本体
	"\n\n%reference3\n\n"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		"\![*]\q[";--;MENUITEM("次のページへ");--;",]\n/
		\![*]\q[";--;MENUITEM("行ってみる");--;",%reference1]\n/
		\![*]\q[";--;MENUITEM("行かない");--;",ChoiceCancel]"
	}
	else
	{
		//---- 次のページがない場合
		"\![*]\q[";--;MENUITEM("行ってみる");--;",%reference1]\n/
		\![*]\q[";--;MENUITEM("行かない");--;",ChoiceCancel]\e"
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\0\s[0]%reference0、こうしんは無いみたいです。\e"
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	"\1\s[10]ヘッドラインセンスに失敗しました。\n\n理由："
	--
	if reference0 == "can't download"
	{
		"ダウンロード失敗。"
	}
	elseif reference0 == "can't analyze"
	{
		"ヘッドライン解析失敗。"
	}
	else
	{
		"謎。"
	}
	--
	"\e"
}


//**** ファイル作成関連 *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\0\s[0]あっぷでーたふぁいる、つくってます。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\0\s[5]できました。\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\0\s[5]なー。つくってます。\e"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\0\s[5]「%reference0」の「なー」ふぁいる\n「%reference1」、できました。\e"
}

//****　時計合わせ　*********************************************************************
//**** みか (http://homepage2.nifty.com/ko-ki/) の辞書を参考にしました。感謝＞こーき氏

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\0\s[0]とけい、みてきます。\n%reference0 に、せつぞくちゅう。\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
OnSNTPCompare
{
	SSNTP = reference1
	LSNTP = reference2
	"\0\s[0]\_qこっち：%LSNTP[1]月%LSNTP[2]日%LSNTP[3]時%LSNTP[4]分%LSNTP[5]秒。\_q\n/
	\_qむこう：%SSNTP[1]月%SSNTP[2]日%SSNTP[3]時%SSNTP[4]分%SSNTP[5]秒。\_q\n\n"
	--
	if reference3 == 0
	{
		"\s[5]うーん、ぴったり。\e"
	}
	else
	{
		"\0\n\s[0]%reference3びょう、ずれてます。\n\n/
		\q0[OnSNTPEXECUTE][じかんをあわせて]/
		\q1[OnSNTPCANCEL][そのままでいいよ]\e"
	}
}

//----　時計合わせ実行 ------------------------------------------------------------------
OnSNTPEXECUTE
{
	"\0\s[5]はい、あわせました。\6\e"
}

//----　時計合わせ中止 ------------------------------------------------------------------
OnSNTPCANCEL
{
	"\0\s[0]ちゅうしー。\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\0\s[4]しっぱいー。\e"
}


//**** そのほか *************************************************************************
//---- URLドロップ -----------------------------------------------------------

OnURLDropping
{
	"\0\s[0]\_q%reference0から、だうんろーど、してます。\_q\e"
}

OnURLDropped
{
	"\0\s[5]だうんろーど、できました。\e"
}

OnURLDropFailure
{
	if reference1 == "timeout"
	{
		//---- タイムアウトした
		"\1\s[10]タイムアウト。\0\s[4]%username、たいむあうと、だって。\e"
	}
	elseif reference1 == "artificial"
	{
		//---- ユーザー自身で中止
		"\0\s[0]ちゅうしー。\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\1\s[10]%reference0、だって。\w5\0\s[4]しっぱいー。\e"
	}
}

//---- ファイルドロップ -----------------------------------------------------------
OnFileDrop2
{
	Filename = reference0
	_file = TOLOWER(Filename)
	//壁紙変更
	if ".png" _in_ _file || ".jpg" _in_ _file || ".jpeg" _in_ _file ||".bmp" _in_ _file
	{
		"/
		\0\s[5]かべがみに、する？\n\n[half]/
		\![*]\q[";--;MENUITEM("まんなかに");--;",ChoiceWallchange0]\n/
		\![*]\q[";--;MENUITEM("ならべて");--;",ChoiceWallchange1]\n/
		\![*]\q[";--;MENUITEM("かくだいする");--;",ChoiceWallchange2]\n/
		\![*]\q[";--;MENUITEM("やっぱりやめた");--;",CANCEL]\e"
	}
	//音楽再生
	elseif ".mid" _in_ _file || ".mp3" _in_ _file || ".wav" _in_ _file || ".wma" _in_ _file ||  ".au" _in_ _file || ".ogg" _in_ _file
	{
		FUNCTIONEX("mciaudior.dll","stop")
		FUNCTIONEX("mciaudior.dll", "load", "%Filename")
		"\0\s[5]\![raise,OnPlayMusic]音楽ふぁいる、さいせいちゅう。\w5\n\s[5]止めたいときは、%keronameのあたまを\nダブルクリックしてね。\e"
	}
}


ChoiceWallchange0
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "0")
	"\0\s[5]かべがみに、しました。\e"
}

ChoiceWallchange1
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "1")
	"\0\s[5]かべがみに、しました。\e"
}

ChoiceWallchange2
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "2")
	"\0\s[5]かべがみに、しました。\e"
}

//---mciaudior.dll呼び出し、開放------------

OnPlayMusic
{
	FUNCTIONEX("mciaudior.dll", "play")
}

OnStopMusic
{
	FUNCTIONEX("mciaudior.dll", "stop")
}

//---- 呼び名選択 -----------------------------------------------------------

//---- 質問
ChoiceUsernameEntry
{
	"\0\s[0]うーんと・・・\n\n/
	\![*]\q[";--;MENUITEM("「お父さん」と呼んでね。");--;",Gender4]\n/
	\![*]\q[";--;MENUITEM("「お兄ちゃん」だよ。");--;",Gender5]\n/
	\![*]\q[";--;MENUITEM("「お母さん」と呼んでね。");--;",Gender6]\n/
	\![*]\q[";--;MENUITEM("「お姉ちゃん」だよ。");--;",Gender7]\e"
}

//----性別
Gender0
{
	Gender = 0
	username = "おとうさん"
	"\_w[420]\0\s[5]おとうさん\w8・・・？\w5\n\s[1]わーい！\w5\n\nおとうさん、おとうさん！\w8\w8\1\s[10]よかったな。\e"
}

Gender1
{
	Gender = 0
	username = "おにいちゃん"
	"\_w[420]\0\s[5]おにいちゃん？\w8・・・\s[1]おにいちゃん！\w8\w8\1\s[10]よかったな。\e"
}

Gender2
{
	Gender = 1
	username = "おかあさん"
	"\_w[420]\0\s[5]おかあさん？\w8・・・\s[1]おかあさん！\w8\w8\1\s[10]よかったな。\e"
}

Gender3
{
	Gender = 1
	username = "おねえちゃん"
	"\_w[420]\0\s[5]おねえちゃん？\w8・・・\s[1]おねえちゃん！\w8\w8\1\s[10]よかったな。\e"
}

//----消滅指示後の性別
Gender4
{
	Gender = 0
	username = "おとうさん"
	"\_w[420]\0\s[0]おとうさん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender5
{
	Gender = 0
	username = "おにいちゃん"
	"\_w[420]\0\s[5]おにいちゃん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender6
{
	Gender = 1
	username = "おかあさん"
	"\_w[420]\0\s[5]おかあさん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender7
{
	Gender = 1
	username = "おねえちゃん"
	"\_w[420]\0\s[5]おねえちゃん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}



//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- 花柚呼び出し ---------------------------------------------------------------
OnCallHanayu
{
	FUNCTIONEX("hanayu.dll", "show")
}

OnReleaseHanayu
{
	FUNCTIONEX("hanayu.dll", "hide")
}

//---- ごみ箱を空にする -----------------------------------------------------------
ChoiceGarbagecan
{
	"\0\t\s[5]ごみすて、いってきまーす。\w9\w9\s[-1]\b[-1]\![raise,OnGarbagecanEmpty]\_w[2500]\c\s[5]ただいまー\e"
}

OnGarbagecanEmpty
{
	_gomi = FUNCTIONEX("gomi.dll", "-f")
}