/////切り替えコア//////////////////////////////////////////////////////////
TranslateSystemChar
{
  _text = TOSTR(_argv[0])
  _text = RE_REPLACE(_text,"[ !%(CHR(0x22))%(CHR(0x25))#$&()*+,-/:;<=>?@\[\]`{|}~]","_")
  _text
}

ExecuteChangeCallTalk
{
  if STRLEN(reference2) {
    _ghostname = TranslateSystemChar(reference2)
    
    _funcname = "%(_argv[0])_%(_ghostname)"
    if ISFUNC(_funcname) {
      _script = EVAL(_funcname)
      if STRLEN(_script) != 0 {
        _script
        return
      }
    }
  }

  _ghostname = TranslateSystemChar(reference0)
  
  _funcname = "%(_argv[0])_%(_ghostname)"
  if ISFUNC(_funcname) {
    _script = EVAL(_funcname)
    if STRLEN(_script) != 0 {
      _script
      return
    }
  }

  _funcname = "%(_argv[0])Other"
  if ISFUNC(_funcname) {
    _script = EVAL(_funcname)
    if STRLEN(_script) != 0 {
      _script
      return
    }
  }

  if _argc >= 2 {
    _script = EVAL(_argv[1])
    if STRLEN(_script) != 0 {
      REPLACE(_script,"\-","")
      return
    }
  }
}
 
OnGhostChanging
{
	ExecuteChangeCallTalk("OnGhostChanging","OnClose")
}

OnGhostChanged
{
	起動共通スクリプト
	--
	ExecuteChangeCallTalk("OnGhostChanged","OnBoot")
}

OnGhostCalling
{
	ExecuteChangeCallTalk("OnGhostCalling")
}

OnGhostCalled
{
	起動共通スクリプト
	--
	ExecuteChangeCallTalk("OnGhostCalled","OnBoot")
}

OnGhostCallComplete
{
	ExecuteChangeCallTalk("OnGhostCallComplete")
}

OnOtherGhostClosed
{
	ExecuteChangeCallTalk("OnOtherGhostClosed")
}
/////切り替えコア//////////////////////////////////////////////////////////

//---- 他のゴーストへ切り替え -----------------------------------------------------------
OnGhostChangingOther
{
	engaged = RAND(255) + 1 // いいかげんな許婚の数。ランダム。
	//浮子屋さんとTomahawkさんからのネタ。有難うございました。
	"\0\s[33]%reference0ちゃんは、\w5\n\s[46]あたしの%engaged番目の許婚〜。\n\n\w8\w8\1\s[12]%reference0さんに、ご迷惑では？\n\n\w8\w8\0\s[40]え、そうかなぁ？\w9\n\s[33]じゃあ、\w5%keronameの許婚〜\w8\w8\1\s[10]・・・\s[12]ふう。\w9\e"
}


//---- 他のゴーストから切り替り ---------------------------------------------------------
OnGhostChangedOther
{
	挨拶
}

//--- 月の裏のうさぎ王国

OnGhostChanging_らんらん
{
	"\1\s[10]\0\s[0]ちょっと、出かけてきます。\w9\e"
}


OnGhostChanged_らんらん
{
	"\1\s[10]\0\s[5]ただいまー。\e"
}