///////// 文　ゴーストテンプレート
///////// 種々のイベント辞書
///////// copyright (C) 2002 umeici.

//**** インストール関連 *****************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	"\1\s[10]\0\s[6]インストール中・・・\e"
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	"\0\s[0]"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"「%reference1」、インストール完了。"
	--
	if reference0 == "ghost"
	{
		Ghostname = reference1
		"/
		交代する？\n\n/
		\![*]\q[%(MENUITEM('よろしく')),ChoiceGhostchange0]\n/
		\![*]\q[%(MENUITEM('いや、あとで')),ChoiceGhostchange1]\e"
	}
	else
	{
		"\s[0]\e"
	}
}

//ゴースト交代可否
ChoiceGhostchange0
{
	"/
	\cでは、%Ghostnameさんと交代します。\w5\n/
	\s[81]たまにうまく行かない場合もあるので、\w5\n/
	\s[82]そのときは手動で切り替えてください。/
	\w8\w8\![change,ghost,%Ghostname]\e"
}

ChoiceGhostchange1
{
	"\0\s[30]あ、いいの？\e"
}

//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	"\0\s[3]インストール失敗。\w5\n理由：%reference0。\e"
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	"\0\s[40]これは、%reference0用の\nアーカイブ。\w5\n\n\s[0]直接渡してあげてね。\e"
}


//**** 消滅関連 *************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	"\1\s[110]\0\s[52]・\w3・\w3・\w3・\w3・\w3・\w3・\e"
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	"\0\s[52]・\w3・\w3・\w3・\w3・\w3・\w3・/
	\1\s[10]縁が無かったのです。\w5\nまた、どこかで会いましょう。\w9\w9\e"
}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	"\0s\[5]\1\s[12]まだ、暫く居られるようです。\w8\0\s[5]うん。\e"
}

//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	"\0\s[52]%reference0、かわいそう・・・\n\n\w5\1\s[12]明日は我が身でしょう・・・\e"
}

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	"\1\s[10]\0\s[0]「めーる」が届いているか、見てこよ。\e"
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\0\s[0]「めーる」は、無かったよ。\e"
	}
	else
	{
		//---- メールが届いていた
		"\0\s[5]めーる、が来てるよ。\w5\n%reference0通、%reference1ばいと、だって。\e"
	}
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウト
		"\0\s[3]\1\s[12]めーるさーばー、に繋がりません。\w8\0\s[3]あいたたた。\e"
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		"\0\s[3]\1\s[12]めーるさーばー、から蹴られました。\w8\0\s[3]あいたたた。\e"
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		"\0\s[3]\1\s[12]設定を間違っていませんか？\w8\0\s[3]もう一度、見直してください。\e"
	}
	else
	{
		//---- 原因不明
		"\0\s[3]\1\s[12]失敗。\w5\n・・・原因不明です。\w8\0\s[3]うーん。\e"
	}
}


//**** ネットワーク更新 *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	if reference3 == "baseware"
	{
		"\0\s[0]ベースウェアのネットワーク更新を始めます。\e"
	}
	else
	{
		"\0\s[0]ネットワーク更新、開始します。\e"
	}
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
	GetSender = sender
	Getfiles = reference0+1
	if Getfiles >= 10
	{
		"\0\s[32]ずいぶん沢山あるね。\w8\1\s[10]急ぎましょう。\e"
	}
	else
	{
		if GetSender == "NiseRingo"
		{
			"\0\s[40]%reference0個だね・・・\e"
		}
		else
		{
			"\0\s[40]%Getfiles個だね・・・\e"
		}
	}
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\0\s[0]特に、無かったみたい。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\1\s[10]\0\s[38]終わりー。\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\0\s[34]タイムアウト、だって。"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\0\s[42]MD5値が違っているみたい。"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\0\s[7]%reference0、だって。"
	}
	--
	"\w5\n\n\s[3]ネットワーク更新、失敗。\e"
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	if Getfiles >= 10
	{
		"\0\s[0]\n\_q%reference0\nのダウンロード開始。\_q\e"
	}
	else
	{
		"\0\s[0]\n\_q%reference0\_q\nのダウンロード開始。\e"
	}
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	if Getfiles >= 10
	{
		"\_q\0\s[33]MD5値のチェックを開始します。\_q\e"
	}
	else
	{
		"\0\s[33]MD5値のチェックを開始します。\e"
	}
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	if Getfiles >= 10
	{
		"\_q\0\s[31]おっけー\_q\e"
	}
	else
	{
		"\0\s[31]おっけー\e"
	}
}

//**** ヘッドラインセンス ***************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\1\s[10]\0\s[0]%reference0ヘッドラインを取得するぞ。\e"
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		//---- 最初のページ
		"\0\b2\s[0]%reference0ヘッドライン第1ページ。"
	}
	elseif reference2 == "Next"
	{
		//---- 真ん中あたりのページ
		"\0\b2\s[0]%reference0ヘッドライン、続き。"
	}
	elseif reference2 == "Last"
	{
		//---- 最後のページ
		"\0\b2\s[0]%reference0ヘッドライン、これが最後のページ。"
	}
	--
	//---- ヘッドライン本体
	"\n\n%reference3\n\n"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		"\![*]\q[%(MENUITEM('次のページへ')),]\n/
		\![*]\q[%(MENUITEM('行ってみる')),%reference1]\n/
		\![*]\q[%(MENUITEM('行かない')),ChoiceCancel]"
	}
	else
	{
		//---- 次のページがない場合
		"\![*]\q[%(MENUITEM('行ってみる')),%reference1]\n/
		\![*]\q[%(MENUITEM('行かない')),ChoiceCancel]\e"
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\0\s[0]更新はないって。\e"
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	"\0\s[3]ヘッドラインセンスに失敗。\n\n"
	--
	if reference0 == "can't download"
	{
		"理由：ダウンロードの失敗。"
	}
	elseif reference0 == "can't analyze"
	{
		"理由：ヘッドライン解析の失敗。"
	}
	else
	{
		"理由は・・・よく分かんない。"
	}
	--
	"\e"
}


//**** ファイル作成関連 *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\1\s[10]\0\s[6]アップデータファイル、作成中。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\0\s[5]完成〜。\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\1\s[10]\0\s[6]narファイル、作成中。\e"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\0\s[5]「%reference0」の「なー」ファイル\n「%reference1」、完成〜。\e"
}

//****　時計合わせ　*********************************************************************
//**** みか (http://homepage2.nifty.com/ko-ki/) の辞書を参考にしました。感謝＞こーき氏

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\0\s[6]時計あわせを開始します。\n\n%reference0\n\nに接続します。\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
OnSNTPCompare
{
	SSNTP = reference1
	LSNTP = reference2
	"\0\s[0]\_q現在時刻　：%LSNTP[1]月%LSNTP[2]日%LSNTP[3]時%LSNTP[4]分%LSNTP[5]秒。\_q\n/
	\_qSNTPServer：%SSNTP[1]月%SSNTP[2]日%SSNTP[3]時%SSNTP[4]分%SSNTP[5]秒。\_q\n\n"
	--
	if reference3 == 0
	{
		"\s[33]ぴったり合ってる。\w8\n\s[0]このままにしておくね。\e"
	}
	else
	{
		"\s[0]ということは、%reference3秒ずれています。\n\s[40]えーと・・・\n\n\6\w2\n\1\s[12]合わせておきました。\0\s[8]はやっ。\e"
	}
}

//----　時計合わせ実行 ------------------------------------------------------------------
OnSNTPEXECUTE
{
	"\0\s[0]時刻を合わせました。\6\e"
}

//----　時計合わせ中止 ------------------------------------------------------------------
OnSNTPCANCEL
{
	"\0\s[0]中止。\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\0\s[4]時計あわせ、失敗。\e"
}


//**** そのほか *************************************************************************
//---- 壁紙変更 -----------------------------------------------------------
OnFileDrop2
{
	Filename = reference0
	_file = TOLOWER(Filename)
	//壁紙変更
	if ".png" _in_ _file || ".jpg" _in_ _file || ".jpeg" _in_ _file ||".bmp" _in_ _file
	{
		ChoiceWallchange
	}
	//音楽再生
	elseif ".mid" _in_ _file || ".mp3" _in_ _file || ".wav" _in_ _file || ".wma" _in_ _file || ".ogg" _in_ _file
	{
		FUNCTIONEX("mciaudior.dll","stop")
		FUNCTIONEX("mciaudior.dll", "load", "%Filename")
		"\0\s[25]\![raise,OnPlayMusic]音楽ファイル、再生中。\w8\1\s[10]止めたいときは、\nわたくしのの頭をダブルクリックして下さい。\e"
	}
}


ChoiceWallchange
{
	"/
	\0\s[30]あ、画像ファイル。\n壁紙にするの？\n\n[half]/
	\![*]\q[%(MENUITEM('中央に')),ChoiceWallchange0]\n/
	\![*]\q[%(MENUITEM('並べて設定')),ChoiceWallchange1]\n/
	\![*]\q[%(MENUITEM('拡大')),ChoiceWallchange2]\n/
	\![*]\q[%(MENUITEM('やっぱりやめた')),ChoiceCancel]\e"
}


ChoiceWallchange0
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%(CHR(34))%(Filename)%(CHR(34))", "0")
	"\0\s[5]壁紙にしました。\e"
}

ChoiceWallchange1
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%(CHR(34))%(Filename)%(CHR(34))", "1")
	"\0\s[5]壁紙にしました。\e"
}

ChoiceWallchange2
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%(CHR(34))%(Filename)%(CHR(34))", "2")
	"\0\s[5]壁紙にしました。\e"
}

//---mciaudior.dll呼び出し、開放------------

OnPlayMusic
{
	FUNCTIONEX("mciaudior.dll", "play")
}

OnStopMusic
{
	FUNCTIONEX("mciaudior.dll", "stop")
}


//---- URLドロップ -----------------------------------------------------------
//---- CROW でゴーストインストーラからゴーストをインストールを始めた時にも呼ばれます。

OnURLDropping
{
	"\1\s[10]\0\s[0]\_q%reference0から、ダウンロード中。\_q\e"
}

OnURLDropped
{
	"\0\s[5]ダウンロード、終了。\e"
}

OnURLDropFailure
{
	if reference1 == "timeout"
	{
		//---- タイムアウトした
		"\0\s[3]タイムアウトしました。失敗。\e"
	}
	elseif reference1 == "artificial"
	{
		//---- ユーザー自身で中止
		"\0\s[0]中止？\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\0\s[3]失敗。\e"
	}
}

//---- ネットワークが重い -----------------------------------------------------
OnNetworkHeavy
{
	"\0\s[34]なんだか重い・・・\e"
}


//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- 花柚呼び出し ---------------------------------------------------------------
OnCallHanayu
{
	FUNCTIONEX("hanayu.dll", "show")
}

OnReleaseHanayu
{
	FUNCTIONEX("hanayu.dll", "hide")
}