///////// 文　ゴーストテンプレート
///////// 起動/終了/切り替えトーク辞書
///////// copyright (C) 2002 umeici.

OnGhostLoad
{
	//---- 花柚起動
	FUNCTIONLOAD("hanayu.dll")

	Timermode = 0		// タイマー処理モード初期化
	LastTalk  = ""		// 直前の会話を初期化

	//連続触りカウント初期化
	Stroked_the_head = 0
	Stroked_the_bust = 0
	Stroked_the_under = 0

}

起動共通スクリプト
{
	movement_status

}

//**** 初回起動 *************************************************************************

//---- OnFirstBootイベント --------------------------------------------------------------
OnFirstBoot
{
	//---- 変数の初期化
	username         = "ご主人さま"
	stroke           = 0	// 撫で判定用
	teachusername    = 0	// ユーザー名覚え用
	mikireflag       = 0	// 見切れ処理用
	communicateratio = 0	// コミュニケート開始率[%]
	movement         = 0	// 画面下部固定

	起動共通スクリプト
	--
	//---- Vanishカウントを見て、真の初回か否かを判定する
	if reference0 == 0
	{
		//---- ほんとうに初めての起動
		favorite  = 0	// 好感度初期化
		"\1\s[10]\0\s[38]やっほー、はじめまして。\w8\n\n\s[0]あたしは、白うさぎの「%selfname」。\n\n\w8\w8\1\s[10]わたくしは、黒うさぎの「%keroname」です。\w8\w8\n\n\_sこれから、よろしくお願いします。\_s/
		\x\0\s[30]あのー、\w5\s[5]お名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
	else
	{
		//---- 再インストール後の初回起動
		favorite = -10 * reference0	// 好感度初期化
		"\1\s[10]\0\s[6]\w3・\w3・\w3・\w3・\w3・\w3・\s[30]あれ？\w8\w8\n\s[3]また、ここ？\n\n\w8\w8\1\s[11]・・・帰りますか？\w8/
		\0\s[32]うーん、%reference0回も追い返されたしね\w1・\w1・\w1・\w9\s[5]でも、いっか。\x/
		\x\0\s[30]あのー、\s[0]改めてお名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
}


//**** 通常の起動 ***********************************************************************

//---- OnBootイベント -------------------------------------------------------------------
OnBoot
{
	_tmp = 月出没時刻設定 // 月の出・入り時刻をもとめておく（都道府県が設定されていなければ何もされない）
	起動共通スクリプト
	--
	// 挨拶処理
	挨拶
}

//---- 朝/昼/夜などをおおざっぱに調べる関数 -------------------------------------------
GetTimeSlot
{
	_m = month
	_h = hour
	
	if _m >= 5 && _m <= 9 { //日の長い期間補正
		if _h >= 5 && _h <= 10 {
			"朝"
		}
		elseif _h >= 11 && _h <= 13 {
			"昼"
		}
		elseif _h >= 14 && _h <= 17 {
			"日中"
		}
		elseif _h >= 18 && _h <= 22 {
			"夜"
		}
		else {
			"深夜"
		}
	}
	else {
		if _h >= 5 && _h <= 10 {
			"朝"
		}
		elseif _h >= 11 && _h <= 13 {
			"昼"
		}
		elseif _h >= 14 && _h <= 16 {
			"日中"
		}
		elseif _h >= 17 && _h <= 22 {
			"夜"
		}
		else {
			"深夜"
		}
	}
}


//**** 終了 *****************************************************************************

//---- OnCloseイベント ------------------------------------------------------------------
OnClose
{
	"\1\s[10]終わりですか？\n\n\w5\0"
	--
	_timeslot = GetTimeSlot
	if _timeslot == "朝"
	{
		//---- 朝に終了
		"\s[48]ご主人さまぁん。\w5\nあのぅ、\w5お外に出してくれませんこと？\w8\w8\1\s[12]いきなりなんです。気持ち悪い。"
		"\s[34]外に出て遊びたい・・・\w5\n\s[41]出たい、\w5出たい、\w5出たい！\w8\w8\1\s[12]落ち着きなさい。"
	}
	elseif _timeslot == "昼" || _timeslot == "日中"
	{
		//---- 昼/日中に終了
		"\s[40]ねえ、%keroname。\w5\nあの柱、かじってみない？\w8\w8\1\s[12]また怒られますよ。"
		"\s[3]%username、お出かけ？\w5\n\s[32]いいなー。どこいくの？\w8\w8\1\s[12]やれやれ。"
	}
	else
	{
		//---- 夜/深夜に終了
		"\s[6]あたしたちも休む？\w8\w8\1\s[12]そうしましょう。\w5\nおやすみなさい。"
	}
	--
	"\w9\w9\-\e"
}


//**** 最小化からの復帰 *****************************************************************

//---- OnWindowStateRestoreイベント -----------------------------------------------------
OnWindowStateRestore
{
	"\1\s[13]\0\s[52]すみっこは狭い・・・\w8\w8\1\s[13]だからといって暴れないで下さい、%selfname。\e"
}



//---- シェルチェンジ開始 ---------------------------------------------------------------
OnShellChanging
{
	"\0\s[0]着替え中・・・\e"
}

//---- シェルチェンジ完了 ---------------------------------------------------------------
OnShellChanged
{
	"%(movement_status)\0\s[5]どうですか？%username？\e"
}