///////// 文　ゴーストテンプレート
///////// 汎用アプリケーション/どりふ/きのこ辞書
///////// copyright (C) 2002 umeici.

//**** 汎用アプリケーション *************************************************************

//---- 起動 -----------------------------------------------------------------------------
OnApplicationBoot
{
	"\0\s[0]%reference0、起動。\e"
}

//---- 終了 -----------------------------------------------------------------------------
OnApplicationClose
{
	"\0\s[0]%reference0、終了。\e"
}

//---- ファイルオープン -----------------------------------------------------------------
OnApplicationFileOpen
{
	"\0\s[0]%reference1を開いたぞ。\e"
}


//**** きのこ ***************************************************************************

//---- 生えた ---------------------------------------------------------------------------
OnKinokoObjectCreate
{
	"\0\s[4]なんじゃこれは。\1\s[10]%reference0デスネ・・・\w8\e"
}

//---- 消えた ---------------------------------------------------------------------------
OnKinokoObjectDestroy
{
	"\0\s[0]ふむ、消えたか。\e"
}

//---- バッテリーが低下 -----------------------------------------------------------------
OnBatteryLow
{
	"\0\s[0]バッテリーが無くなってきておる。\w5\n気をつけるがよいぞ。\e"
}

//---- システムリソースが低下 -----------------------------------------------------------
OnSysResourceLow
{
	"\0\s[0]システムリソースが少なくなってきておる。\w5\n気をつけるがよいぞ。\e"
}


//**** どりふ ***************************************************************************

//---- OnNekodorifObjectHitイベント -----------------------------------------------------
OnNekodorifObjectHit
{
	if reference4 == "ストラ"	// ここにsakura名を指定
	{
		ObjectHitSakura
	}
	else
	{
		ObjectHitKero
	}
}

//---- 本体側に当たった -----------------------------------------------------------------
ObjectHitSakura
{
	if reference2[0] == "pain" || reference2[0] == "stab"
	{
		"\0\s[7]何をする！\e"
	}
	elseif reference2[0] == "surprise" || reference2[0] == "huge"
	{
		"\0\s[2]なんじゃ？\e"
	}
	elseif reference2[0] == "love" || reference2[0] == "elegant" || /
		reference2[0] == "pretty" || reference2[0] == "food"
	{
		"\0\s[5]ほう。\e"
	}
	else
	{
		"\0\s[0]ふむ？\w5\n%reference0か。\e"
	}
}

//---- kero側に当たった -----------------------------------------------------------------
ObjectHitKero
{
	if reference2[0] == "pain" || reference2[0] == "stab"
	{
		"\1\s[10]グ・・・\e"
	}
	else
	{
		"\1\s[10]ムム。\e"
	}
}