///////// 文　ゴーストテンプレート
///////// マウス入力関連辞書
///////// copyright (C) 2002-2003 umeici.

//**** 撫で反応 *************************************************************************

//---- OnMouseMoveイベント --------------------------------------------------------------
OnMouseMove
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側の撫で
		MouseMoveSakura
	}
	else
	{
		//---- kero側の撫で
		MouseMoveKero
	}
}

//---- 本体側の撫で反応 -----------------------------------------------------------------
MouseMoveSakura
{
	if reference4 != ""
	{
		//----どこかが撫でられている
		stroke++
		//---- 撫でられた量が一定量に達したら「なでられている」と判断
		if stroke >= 64
		{
			//---- 撫でられた。撫でられた部位を見てトークする
			if reference4 == "Head"
			{
				ChoiceHead
			}
			elseif reference4 == "Face"
			{
				ChoiceFace
			}
			elseif reference4 == "Bust"
			{
				ChoiceBust
			}
			elseif reference4 == "Crotch"
			{
				ChoiceCrotch
			}
			stroke = 0
		}
	}
	else
	{
		// 定義された部位はどこも撫でられていない
		stroke = 0
	}
}

//---- kero側の撫で反応 -----------------------------------------------------------------
MouseMoveKero
{
	//---- なし
}


//**** つつかれ反応 *********************************************************************

//---- OnMouseDoubleClickイベント -------------------------------------------------------
OnMouseDoubleClick
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側のつつかれ
		MouseDoubleClickSakura
	}
	else
	{
		//---- kero側のつつかれ
		MouseDoubleClickKero
	}
}

//---- 本体側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickSakura
{
	//---- 顔つつかれ処理
	if reference4 == "Face"
	{
		OnAiTalk
	}
	elseif reference4 == "Head"
	{
		OnStopMusic
	}
	elseif reference4 == "Bust"
	{
		ChoiceBust
	}
	elseif reference4 == "Crotch"
	{
		ChoiceCrotch
	}
	else
	{
		//---- 顔以外のつつきでメニュー展開
		OpenMenu
	}
}

//---- kero側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickKero
{
}


//---- 反応まとめ -------------------------------------------------------------
ChoiceHead : nonoverlap
{
	if bootcount <= 2
	{
		"\0\s[38]・\w3・\w3・\w3・\w3・\w3・\w3\e"
		"\0\s[31]・\w3・\w3・\w3・\w3・\w3・\w3\e"
	}
	elseif bootcount <= 9
	{
		"\0\s[35]あり・\w3・\w3・\w3がとう・\w3・\w3・\w3\e"
		"\0\s[32]あり・\w3・\w3・\w3がとう・\w3・\w3・\w3\e"
	}
	else
	{
		"\0\s[34]・\w3・\w3・\w3ありがとう。\e"
	}
}

ChoiceFace : nonoverlap
{
	if bootcount <= 2
	{
		"\0\s[38]・\w3・\w3・\w3・\w3・\w3・\w3\e"
		"\0\s[31]・\w3・\w3・\w3・\w3・\w3・\w3\e"
	}
	elseif bootcount <= 9
	{
		"\0\s[35]・\w3・\w3・\w3？？？\e"
		"\0\s[32]・\w3・\w3・\w3？？？\e"
	}
	else
	{
		"\0\s[34]何かの、おまじない？\e"
	}
}

ChoiceBust : nonoverlap
{
	if bootcount <= 2
	{
		"\0\s[38]・\w3・\w3・\w3・\w3・\w3・\w3\w9\w9\w9\s[30]\e"
		"\0\s[31]・\w3・\w3・\w3・\w3・\w3・\w3\w9\w9\w9\s[30]\e"
	}
	elseif bootcount <= 9
	{
		"\0\s[35]や、やめて・\w3・\w3・\w3\s[36]\e"
		"\0\s[32]・\w3・\w3・\w3くすぐったい。\e"
	}
	else
	{
		"\1\s[10]\0\s[34]何かの、おまじない？\e"
		"\0\s[38]や、\w5やだよ、\w5\s[30]ぼく・\w3・\w3・\w3！\e"
	}
}


ChoiceCrotch : nonoverlap
{
	if bootcount <= 2
	{
		"\0\s[38]・\w3・\w3・\w3・\w3・\w3・\w3\nひどい・\w3・\w3・\w3\w9\w9\w9\s[30]\e"
		"\0\s[31]・\w3・\w3・\w3・\w3・\w3・\w3\nひどい・\w3・\w3・\w3\w9\w9\w9\s[30]\e"
	}
	elseif bootcount <= 9
	{
		"\0\s[35]や、やめて・\w3・\w3・\w3\s[36]\e"
		"\0\s[36]・\w3・\w3・\w3・\w3・\w3・\w3\e"
	}
	else
	{
		"\0\s[38]そ、そんなとこ・\w3・\w3・\w3！\e"
		"\0\s[38]や、\w5やだよ、\w5\s[30]ぼく・\w3・\w3・\w3！\e"
	}
}