///////// 文　ゴーストテンプレート
///////// マウス入力関連辞書
///////// copyright (C) 2002 umeici.

//**** 撫で反応 *************************************************************************

//---- OnMouseMoveイベント --------------------------------------------------------------
OnMouseMove
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側の撫で
		MouseMoveSakura
	}
	else
	{
		//---- kero側の撫で
		MouseMoveKero
	}
}

//---- 本体側の撫で反応 -----------------------------------------------------------------
MouseMoveSakura
{
	if reference4 != ""
	{
		//----どこかが撫でられている
		stroke++
		//---- 撫でられた量が一定量に達したら「なでられている」と判断
		if stroke >= 64
		{
			//---- 撫でられた。撫でられた部位を見てトークする
			if reference4 == "Head"
			{
				ChoiceHead
			}
			elseif reference4 == "Hands"
			{
				ChoiceHands
			}
			elseif reference4 == "Wing"
			{
				ChoiceWing
			}
			elseif reference4 == "Lip"
			{
				ChoiceLip
			}
			elseif reference4 == "Face"
			{
				ChoiceFace
			}
			elseif reference4 == "Bust"
			{
				ChoiceBust
			}
			elseif reference4 == "Skirt"
			{
				ChoiceSkirt
			}
			elseif reference4 == "Thigh"
			{
				ChoiceThigh
			}
			stroke = 0
		}
	}
	else
	{
		// 定義された部位はどこも撫でられていない
		stroke = 0
	}
}

//---- kero側の撫で反応 -----------------------------------------------------------------
MouseMoveKero
{
	//---- なし
}


//**** つつかれ反応 *********************************************************************

//---- OnMouseDoubleClickイベント -------------------------------------------------------
OnMouseDoubleClick
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側のつつかれ
		MouseDoubleClickSakura
	}
	else
	{
		//---- kero側のつつかれ
		MouseDoubleClickKero
	}
}

//---- 本体側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickSakura
{
	//---- 顔つつかれ処理
	if reference4 == "Face"
	{
		OnAiTalk
	}
	elseif reference4 == "Hands"
	{
		ChoiceHands
	}
	elseif reference4 == "Wing"
	{
		ChoiceWing
	}
	elseif reference4 == "Lip"
	{
		ChoiceLip
	}
	elseif reference4 == "Bust"
	{
		ChoiceBust
	}
	elseif reference4 == "Skirt"
	{
		ChoiceSkirt
	}
	elseif reference4 == "Thigh"
	{
		ChoiceThigh
	}
	else
	{
		//---- 顔以外のつつきでメニュー展開
		OpenMenu
	}
}

//---- kero側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickKero
{
	//---- kero側のつつかれ処理
	if reference4 == "Head2"
	{
		OnStopMusic
	}
	else
	{
		"\1\s[10]なんとなく浮いてます。\e"
	}
}



//---- 反応まとめ -------------------------------------------------------------
ChoiceHead : nonoverlap
{
	"\0\s[34]もう、頭撫でられて喜ぶ年でもないんだけどな。\w8\1\s[10]そのわりに、嬉しそうですね。顔に出すぎ。\e"
	"\0\s[1]\w3・\w3・\w3・ぽっ。\n\n\w8\1\s[12]わざわざ媚売らなくても。\w8\0\s[9]あはは、バレた？\w5\n\s[5]でも、ちょっと嬉しいのはホントだよ。\e"
}

ChoiceHands : nonoverlap
{
	"\0\s[1]て、手をつなぐんですか\w3・\w3・\w3・\w3・\n\s[8]とか言って、照れると思った？\w5\1\s[10]ほっほっほ。\e"
	"\0\s[6]実は「癒しの手」なんだよ。\w5\1\s[10]「一応」ですけどね。\e"
	"\0\s[5]あら。おねーさんと、おててつなぎたいの？\w5\n\s[9]甘えん坊だねー\w5\1\s[10]ほっほっほ。\e"
}

ChoiceWing : nonoverlap
{
	"\0\s[40]きゃはははは！　だ、だから、羽は弱いの！\w5\n\s[41]やめてー、やめてえ！\w5\1\s[12]嫌がっているのか喜んでいるのか、\w5\nよく分かりませんね。\e"
	"\0\s[40]いやぁ、\w4おねがひ、\w4やめて、\w4やめて、\w8\nきゃはははは！\w5\1\s[12]・・・弱みを完全に握られましたね。\e"
}

ChoiceLip : nonoverlap
{
	"\0\s[1]あ、\w3あの、\w3くちびる\w3・\w3・\w3・\w3・\n\s[8]触って喜んでるの？　いやらしー。\w5\1\s[10]ほっほっほ。\e"
	"\0\s[2]うわ！\w5\n\s[32]口に変なの、つっこまないでよ。\w5\1\s[10]おやおや。\e"
}


ChoiceFace : nonoverlap
{
	"\0\s[36]これは、なにかのおまじない？\w5\1\s[10]違うんじゃないですか？\e"
}

ChoiceBust : nonoverlap
{
	"\0\s[1]%usernameなら、いいよ\w3・\w3・\w3・\w3・\n\s[8]なーんて、言うと思った？　このヘンタイ。\w5\1\s[10]ほっほっほ。\e"
	"\0\s[1]そ、そんなところ\w3・\w3・\w3・\w3・\n\s[8]なーんて、恥らうと思った？　バーカ。\w5\1\s[10]ほっほっほ。\e"
	"\0\s[8]ねー%username。\w5\n3次元の女の子には興味ないの？\w5\1\s[10]いろんな人がいますから。\e"
}

ChoiceSkirt : nonoverlap
{
	"\0\s[8]鋼鉄のスカートなのでめくれません。\w5\1\s[10]ほっほっほ。\e"
	"\0\s[4]はー\w3・\w3・\w3・、ヒマだねー。\w5\n\s[8]こんな事してないで、泡の国にでもいってきたら？\w5\1\s[10]私も賛成です。\e"
	"\0\s[8]そんな事して私に構っているヒマあったら、\w5\n少しは仕事したら？\w5\1\s[10]ほっほっほ。\e"
}

ChoiceThigh : nonoverlap
{
	"\0\s[9]リアルで触れる相手いないの？\w5\1\s[10]ほっほっほ。\e"
	"\0\s[8]そんな事して私に構っているヒマあったら、\w5\nお金貯めて女の子触れる店でもいったら？\w5\1\s[10]ほっほっほ。\e"
}