///////// 文　ゴーストテンプレート
///////// メニュー処理辞書
///////// copyright (C) 2002 umeici.

//**** メインメニューの展開 *************************************************************

//---- メインメニュー展開 ---------------------------------------------------------------
OpenMenu
{
	"\0%OpenMenuTalk\n\n/
	\![*]\q[%(MENUITEM('なにか話して')),OnAiTalk]\n"
	--
		if LastTalk != ""
		{
			"\![*]\q[%(MENUITEM('さっきの話を聞きたい')),OnLastTalk]\n"
		}
	--
	"\![*]\q[%(MENUITEM('天使まめ知識')),ChoiceAngelsknowledge]\n/
	\![*]\q[%(MENUITEM('お仕事')),ChoiceAngelworks]\n/
	\![*]\q[%(MENUITEM('しゃべり頻度を変えて')),ChoiceTalkInterval]\n/
	\![*]\q[%(MENUITEM('いっしょに過ごした時間')),ChoiceHanayu]\n/
	\![*]\q[%(MENUITEM('なんでもない')),ChoiceCancel]\e"
}

OpenMenuTalk
{
	"\s[31]はい、何ですか？"
	"\s[5]どうしました？"
}

//---- メニュー項目の後ろにスペースを補完する関数
MENUITEM
{
	_menuitem = _argv[0]
	for _i = GETSTRBYTES(_menuitem) ; _i < 48 ; _i++
	{
		_menuitem += " "
	}
	_menuitem
}


//---- OnChoiceSelectイベント -----------------------------------------------------------
//OnChoiceSelectイベント関数は、全て頭にChoiceとつける（私が分かるように）
OnChoiceSelect
{
	EVAL(reference0)
}

//---- アンカー辞書 --------------------------------------------------
OnAnchorSelect
{
	EVAL(reference0)
}

//**** メニュー項目選択 *****************************************************************

//---- その他のメニュー ---------------------------------------------------------
Modeetc
{
	"/
	\![*]\q[%(MENUITEM('もどる')),OpenMenu]\e"
}


//---- トーク頻度の調整
ChoiceTalkInterval
{
	"\0\s[0]どのくらいがいいのかな？\n\n/
	\q[%(MENUITEM('うるさいくらい')),ChoiceTalkMax]\n/
	\q[%(MENUITEM('ふつう')),ChoiceTalkNormal]\n/
	\q[%(MENUITEM('のんびり')),ChoiceTalkPoor]\n/
	\q[%(MENUITEM('黙ってて')),ChoiceTalkNone]\e"
}

//---- トーク頻度
ChoiceTalkMax
{
	//---- うるさく話す(15秒間隔)
	aitalkinterval = 15
	"\0\s[31]じゃ、張り切っていきます。\e"
}

ChoiceTalkNormal
{
	//---- ふつうに話す(2分間隔)
	aitalkinterval = 120
	"\0\s[5]じゃ、普通に。\e"
}

ChoiceTalkPoor
{
	//---- のんびり話す(5分間隔)
	aitalkinterval = 300
	"\0\s[0]じゃ、のんびりと。\e"
}

ChoiceTalkNone
{
	//---- 話さない
	aitalkinterval = 0
	"\0\s[4]はい、静かにしてます。\e"
}

//---- 直前のトーク再現 -------------------------------------------------------------------------
OnLastTalk
{
	"\0\s[36]え？　\w5さっきの？\w9\w9\w9\c%LastTalk"
	"\0\s[33]えーっと・・・\w9\w9\w9\c%LastTalk"
}

//---- 一緒にいました時間 ---------------------------------------------------------
ChoiceHanayu
{
	"\1\s[10]一週間分の起動時間をグラフ表示します。\w8\w8\![raise,OnCallHanayu]\n\n閉じたいときは、\nグラフをダブルクリックしてください。\e"
}



//---- キャンセル ---------------------------------------------------------
ChoiceCancel
{
	"\0\s[2]え。\e"
	"\0\s[3]えー。\e"
}

//---- メニュー選択タイムアウト ---------------------------------------------------------
OnChoiceTimeout
{
	"\0\s[7]ちゃんと選んでくださいっ！\e"
}