/////切り替えコア//////////////////////////////////////////////////////////
TranslateSystemChar
{
  _text = TOSTR(_argv[0])
  _text = RE_REPLACE(_text,"[ !%(CHR(0x22))%(CHR(0x25))#$&()*+,-/:;<=>?@\[\]`{|}~]","_")
  _text
}

ExecuteChangeCallTalk
{
  if STRLEN(reference2) {
    _ghostname = TranslateSystemChar(reference2)
    
    _funcname = "%(_argv[0])_%(_ghostname)"
    if ISFUNC(_funcname) {
      _script = EVAL(_funcname)
      if STRLEN(_script) != 0 {
        _script
        return
      }
    }
  }

  _ghostname = TranslateSystemChar(reference0)
  
  _funcname = "%(_argv[0])_%(_ghostname)"
  if ISFUNC(_funcname) {
    _script = EVAL(_funcname)
    if STRLEN(_script) != 0 {
      _script
      return
    }
  }

  _funcname = "%(_argv[0])Other"
  if ISFUNC(_funcname) {
    _script = EVAL(_funcname)
    if STRLEN(_script) != 0 {
      _script
      return
    }
  }

  if _argc >= 2 {
    _script = EVAL(_argv[1])
    if STRLEN(_script) != 0 {
      REPLACE(_script,"\-","")
      return
    }
  }
}
 
OnGhostChanging
{
	ExecuteChangeCallTalk("OnGhostChanging","OnClose")
}

OnGhostChanged
{
	起動共通スクリプト
	--
	ExecuteChangeCallTalk("OnGhostChanged","OnBoot")
}

OnGhostCalling
{
	ExecuteChangeCallTalk("OnGhostCalling")
}

OnGhostCalled
{
	起動共通スクリプト
	--
	ExecuteChangeCallTalk("OnGhostCalled","OnBoot")
}

OnGhostCallComplete
{
	ExecuteChangeCallTalk("OnGhostCallComplete")
}

OnOtherGhostClosed
{
	ExecuteChangeCallTalk("OnOtherGhostClosed")
}
/////切り替えコア//////////////////////////////////////////////////////////

//---- 他のゴーストへ切り替え -----------------------------------------------------------
OnGhostChangingOther
{
	//---- 手動切り替え
	if reference1 == "manual" {
		"\0\s[0]%reference0によろしくね。\w9\e"
	}
	else {
		//---- 自動切換え
		"\0\s[8]えーと、%reference0がしゃしゃり出たいと\w5\n言ってるようなので交代します。\w5\1\s[11]そういう口を利くのは止めてください。\e"
	}
}

//---- 他のゴーストから切り替り ---------------------------------------------------------
OnGhostChangedOther
{
	挨拶
}

//---- 自分 ---------------------------------------------------------
OnGhostChanging_ひより＆ふくちー
{
	"\0\s[31]ちょっと、出かけてきまーす。\w9\e"
}

OnGhostChanged_ひより＆ふくちー
{
	"\0\s[2808]\_w[1000]\1\s[10]\0\s[31]ただいまー。\w9\e"
}

//---- ひよみゅ ---------------------------------------------------------
OnGhostChanging_ひよみゅ〜
{
	"\0\s[5]そっくりさんだね。\n\n\w8\1\s[11]%selfnameと違って、大人しそう\0\s[2]\1な娘さんです。\w5\nうらやましい限り。\w8\0\s[32]なによぅ！\w9\e"
}

//---- 偽ひよ ---------------------------------------------------------
OnGhostChanging_偽ひより
{
	"\0\s[5]そっくりさんだね。\w8\1\s[10]茨城弁は、響きが独特で面白そうです。\w9\e"
}