///////// 文　ゴーストテンプレート
///////// 種々のイベント辞書
///////// copyright (C) 2002 umeici.

//**** インストール関連 *****************************************************************

//---- インストール中のメッセージ -------------------------------------------------------
OnInstallBegin
{
	"\1\s[10]\0\s[6]インストールしています。\e"
}

//---- インストール完了メッセージ -------------------------------------------------------
OnInstallComplete
{
	"\0\s[0]"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"「%reference1」、インストールしました。"
	--
	if reference0 == "ghost"
	{
		Ghostname = reference1
		"/
		\n\s[33]交代しますか？\n\n/
		\![*]\q[%(MENUITEM('よろしく')),ChoiceGhostchange0]\n/
		\![*]\q[%(MENUITEM('いや、あとで')),ChoiceGhostchange1]\e"
	}
	else
	{
		"\e"
	}
}

//ゴースト交代可否
ChoiceGhostchange0
{
	"/
	\0\s[0]\cでは、%Ghostnameさんと交代します。\w5\n/
	たまにうまく行かないこともあるので、\w5\n/
	そのときは手動で切り替えてね。\w9\w9/
	\![change,ghost,%Ghostname]\e"
}

ChoiceGhostchange1
{
	"\0\s[0]はーい。\e"
}

//---- インストール失敗メッセージ -------------------------------------------------------
OnInstallFailure
{
	"\0\s[4]インストール、失敗。\w5\n理由：%reference0だって。\e"
}

//---- インストール拒否（他のゴーストのためのアーカイブだった） -------------------------
OnInstallRefuse
{
	"\0\s[33]これは、%reference0さん用の\nアーカイブです。\w5\n\n直接渡してあげてね。\e"
}


//**** 消滅関連 *************************************************************************

//---- 消滅指示 -------------------------------------------------------------------------
OnVanishSelecting
{
	"\1\s[10]\0\s[0]・\w3・\w3・\w8そうだよね、\s[4]ここじゃ役に立たないもんね。\e"
}

//---- 消滅開始 -------------------------------------------------------------------------
OnVanishSelected
{
	"\0\s[9]今度はちゃんと、人間界に降りてくるから。\w5\nさようなら。\w8\1\s[10]短い間ですが、お世話になりました。\w5\nまた会うこともあるでしょう。\w9\e"
}

//---- 消滅中止 -------------------------------------------------------------------------
OnVanishCancel
{
	"\1\s[10]思い直したみたいですよ。\w8\0\s[0]押し間違いかもね。\e"
}

//---- 他のゴーストが消滅して自分に切り替わった -----------------------------------------
OnVanished
{
	"\1\s[10]\0\s[3]明日はわが身、か・・・\w8\w8\1\s[10]%selfnameは天界に帰るだけですから、\nまだマシですよ・・・\e"
}

//---- メールチェック開始 ---------------------------------------------------------------
OnBIFFBegin
{
	"\1\s[10]\0\s[31]メールチェックを開始しまーす。\e"
}

//---- メールチェック成功 ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- メールは無かった
		"\0\s[0]メールはありませんでした。\w8\1\s[12]大量のウィルスメールよりは、\nずっといいかもしれませんね\e"
	}
	else
	{
		//---- メールが届いていた
		"\0\s[5]メールが来てます。\w5\n%reference0通、%reference1バイトです。\e"
	}
}

//---- メールチェック失敗 ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウト
		"\0\s[35]メールサーバに繋がらないよ。\e"
	}
	elseif reference0 == "kick"
	{
		//---- 蹴られた
		"\0\s[35]あいたた。\w5\nメールサーバから蹴られました。\e"
	}
	elseif reference0 == "defect"
	{
		//---- 設定誤り
		"\0\s[35]設定ミスの可能性が大。\w5\nメールチェックの設定を見なおしてね。\e"
	}
	else
	{
		//---- 原因不明
		"\0\s[35]原因はわからないけど、失敗。\e"
	}
}


//**** ネットワーク更新 *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	if reference3 == "baseware"
	{
		"\0\s[31]ベースウェアのネットワーク更新、開始しまーす。\e"
	}
	else
	{
		"\0\s[31]ネットワーク更新、開始しまーす。\e"
	}
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
	GetSender = REQ.VALUE("Sender")
	Getfiles = reference0+1
	if GetSender == "NiseRingo"
	{
		"\0\s[0]更新ファイルの数は\w3\n%reference0個。\e"
	}
	else
	{
		"\0\s[0]更新ファイルの数は\w3\n%Getfiles個。\e"
	}
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\0\s[0]更新、なかったよ。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\1\s[10]\0\s[5]更新、おわりー。\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\0\s[35]タイムアウトです。"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\0\s[35]MD5値が違ってます。"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\0\s[35]%reference0、だって。"
	}
	--
	"\n\nネットワーク更新、失敗。\e"
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	"\0\s[0]\n\_q%reference0\_q\nのダウンロード開始。\e"
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	"\0\s[33]MD5値のチェックを開始します。\e"
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	"\0\s[5]ん・・・、オッケー。\e"
}

//**** ヘッドラインセンス ***************************************************************

//---- ヘッドラインセンス開始 -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\1\s[10]\0\s[0]%reference0ヘッドラインを取得します。\e"
}

//---- ヘッドライン読み上げ -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- はじめのセリフ
	if reference2 == "First" || reference2 == "First and Last"
	{
		//---- 最初のページ
		"\0\b2\s[0]%reference0ヘッドライン第1ページ。"
	}
	elseif reference2 == "Next"
	{
		//---- 真ん中あたりのページ
		"\0\b2\s[0]%reference0ヘッドライン、続き。"
	}
	elseif reference2 == "Last"
	{
		//---- 最後のページ
		"\0\b2\s[0]%reference0ヘッドライン、これが最後のページです。"
	}
	--
	//---- ヘッドライン本体
	"\n\n%reference3\n\n"
	--
	//---- 選択肢
	if reference2 == "First" || reference2 == "Next"
	{
		//---- 次のページがある場合
		"\![*]\q[%(MENUITEM('次のページへ')),]\n/
		\![*]\q[%(MENUITEM('行ってみる')),%reference1]\n/
		\![*]\q[%(MENUITEM('行かない')),ChoiceCancel]"
	}
	else
	{
		//---- 次のページがない場合
		"\![*]\q[%(MENUITEM('行ってみる')),%reference1]\n/
		\![*]\q[%(MENUITEM('行かない')),ChoiceCancel]\e"
	}
}

//---- ヘッドライン更新が無かった -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\0\s[0]更新はないみたいです。\e"
}

//---- ヘッドラインセンス失敗 -----------------------------------------------------------
OnHeadlinesenseFailure
{
	"\0\s[3]ヘッドラインセンスに失敗しました。\n\n"
	--
	if reference0 == "can't download"
	{
		"理由は・・・ダウンロードの失敗。"
	}
	elseif reference0 == "can't analyze"
	{
		"理由は・・・ヘッドライン解析、失敗。"
	}
	else
	{
		"\s[4]理由は・・・よく分かんないです。"
	}
	--
	"\e"
}


//**** ファイル作成関連 *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\1\s[10]\0\s[33]アップデータファイル、作成中。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\0\s[5]できました。\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\1\s[10]\0\s[33]なー、作成中。\e"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\0\s[5]「%reference0」の「なー」ファイル\n「%reference1」、出来ました。\e"
}

//****　時計合わせ　*********************************************************************
//**** みか (http://homepage2.nifty.com/ko-ki/) の辞書を参考にしました。感謝＞こーき氏

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\1\s[10]\0\s[0]時計あわせを開始します。\n\n%reference0\n\nに接続します。\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
OnSNTPCompare
{
	SSNTP = reference1
	LSNTP = reference2
	"\0\s[0]\_q現在時刻　：%LSNTP[1]月%LSNTP[2]日%LSNTP[3]時%LSNTP[4]分%LSNTP[5]秒。\_q\n/
	\_qSNTPServer：%SSNTP[1]月%SSNTP[2]日%SSNTP[3]時%SSNTP[4]分%SSNTP[5]秒。\_q\n\n"
	--
	if reference3 == 0
	{
	"\s[5]ぴったり。\w8\nこのままにしておきます。"
	}
	else
	{
	"%reference3秒ずれています。\6\w2\n\s[5]直しておきました。"
	}
}

//----　時計合わせ実行 ------------------------------------------------------------------
OnSNTPEXECUTE
{
	"\0\s[0]時刻を合わせました。\6\e"
}

//----　時計合わせ中止 ------------------------------------------------------------------
OnSNTPCANCEL
{
	"\0\s[0]中止。\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\0\s[0]時計あわせ失敗。\e"
}


//**** そのほか *************************************************************************
//---- 壁紙変更 -----------------------------------------------------------
OnFileDrop2
{
	Filename = reference0
	_file = TOLOWER(Filename)
	//壁紙変更
	if ".png" _in_ _file || ".jpg" _in_ _file || ".jpeg" _in_ _file ||".bmp" _in_ _file
	{
		"/
		\0\s[5]壁紙に、する？\n\n[half]/
		\![*]\q[%(MENUITEM('真ん中に')),ChoiceWallchange0]\n/
		\![*]\q[%(MENUITEM('並べて')),ChoiceWallchange1]\n/
		\![*]\q[%(MENUITEM('拡大する')),ChoiceWallchange2]\n/
		\![*]\q[%(MENUITEM('やっぱりやめた')),ChoiceCancel]\e"
	}
	//音楽再生
	elseif ".mid" _in_ _file || ".mp3" _in_ _file || ".wav" _in_ _file || ".wma" _in_ _file || ".au" _in_ _file || ".ogg" _in_ _file
	{
		FUNCTIONEX("mciaudior.dll","stop")
		FUNCTIONEX("mciaudior.dll", "load", "%Filename")
		"\0\s[25]\![raise,OnPlayMusic]音楽ファイル、再生中。\w5\n止めたいときは、%keronameのあたまを\nダブルクリックしてね。\e"
	}
}


ChoiceWallchange0
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "0")
	"\0\s[5]壁紙に、しました。\e"
}

ChoiceWallchange1
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "1")
	"\0\s[5]壁紙に、しました。\e"
}

ChoiceWallchange2
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "2")
	"\0\s[5]壁紙に、しました。\e"
}

//---mciaudior.dll呼び出し、開放------------

OnPlayMusic
{
	FUNCTIONEX("mciaudior.dll", "play")
}

OnStopMusic
{
	FUNCTIONEX("mciaudior.dll", "stop")
}


//---- URLドロップ -----------------------------------------------------------
//---- CROW でゴーストインストーラからゴーストをインストールを始めた時にも呼ばれます。

OnURLDropping
{
	"\1\s[10]\0\s[0]\_q%reference0から、ダウンロードしてます。\_q\e"
}

OnURLDropped
{
	"\0\s[5]ダウンロード、できました。\e"
}

OnURLDropFailure
{
	if reference1 == "timeout"
	{
		//---- タイムアウトした
		"\0\s[4]%username、\nタイムアウト、だって。\e"
	}
	elseif reference1 == "artificial"
	{
		//---- ユーザー自身で中止
		"\0\s[0]中止ー。\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\0\s[4]失敗。\e"
	}
}

//---- ネットワークが重い -----------------------------------------------------
OnNetworkHeavy
{
	"\0\s[4]重くて反応しないー。\e"
}
//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- 花柚呼び出し ---------------------------------------------------------------
OnCallHanayu
{
	FUNCTIONEX("hanayu.dll", "show")
}

OnReleaseHanayu
{
	FUNCTIONEX("hanayu.dll", "hide")
}