///////// 文　ゴーストテンプレート
///////// 起動/終了/切り替えトーク辞書
///////// copyright (C) 2002 umeici.

OnGhostLoad : void
{
	// 誕生日が空の場合、ダミーの数値を入れる
	if userBD == ""
	{
		userBD = "3000,13,32"
	}

	FUNCTIONLOAD("hanayu.dll")
	
	Timermode = 0		// タイマー処理モード初期化
	LastTalk         = ""	// 直前の会話を初期化
}

起動共通スクリプト
{
	if basewarename != 'embryo' {
		'\_q\1\![set,alignmenttodesktop,free]\0\_q'
	}
	else {
		''
	}
}

//**** 初回起動 *************************************************************************

//---- OnFirstBootイベント --------------------------------------------------------------
OnFirstBoot
{
	//---- 変数の初期化
	username         = "ユーザーさん"
	stroke           = 0	// 撫で判定用
	teachusername    = 0	// ユーザー名覚え用
	mikireflag       = 0	// 見切れ処理用
	communicateratio = 0	// コミュニケート開始率[%]
	
	起動共通スクリプト
	--
	//---- Vanishカウントを見て、真の初回か否かを判定する
	if reference0 == 0
	{
		//---- ほんとうに初めての起動
		"\0\s[2808]\_w[1000]\1\s[10]\0\s[6]\w3・\w3・\w3・\w3・\w3・\w3・\w8\w8\n\n/
		\1\s[10]うむ、無事に着きました。\w5\n%selfname、仕事場です。目を開けなさい。\w8\w8/
		\0\s[0]\w9\w9\w9\s[2]えっ、\w5\w9\w9\s[21]ええっ？　\w9\w9何よここ？！\w5\n\s[4]狭いよー！　人間界ってこんなに小さかった？\n\n\w8\w8/
		\1\c\s[18]うーむ・\w3・\w3・\w5\nここは人間の使う「ぱそこん」の中です。\w5\n\n\s[12]間違えてしまったものは仕方が無い。\nここでなんとかしましょう。\w8\w8/
		\0\s[4]また、ドジやっちゃった\w3・\w3・\w3・\w8\w8\s[5]\cと、とにかく、自己紹介します。\w5\n\n/
		\s[0]私は、%selfname。新米の天使です。\w5\n\s[1]実は、あなたの守護天使として派遣されたんだけど、\w5\n\s[30]間違ってここへ来ちゃいました。\n\n\w8/
		\1\c\s[10]私の名は、%keroname。\w5\n%selfnameのお目付け役です。\n\n\w8\w8/
		\0\s[0]いろいろご迷惑をかけるかもしれませんが、\n\_sこれから、よろしくおねがいします。\_s/
		\x\0\s[5]あの、改めてお名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
	else
	{
		//---- 再インストール後の初回起動
		"\0\s[2808]\_w[1000]\1\s[10]\0\s[6]\w3・\w3・\w3・\w3・\w3・\w3・\w8\w8\n\n/
		\1\s[10]うむ、無事に着きました。\w9\w9\w9\n\n/
		\0はーい。\n\n\s[0]\w9\w9\w9\s[2]えっ、\w5\w9\w9\s[21]ええっ？　\w9\w9またここ？！\n\n\w8\w8/
		\1\s[18]いけない。この調子じゃまた追い返されます。\w8/
		\0\s[8]もう、%reference0回も追い返されてるしねー。\w8/
		\1\s[10]\c\w1・\w1・\w1・\w9まあ、なんとかやりましょう。/
		\0\s[0]\cそうだね・・・\w5\nまた、よろしくお願いします。\x\0\s[5]あの、改めてお名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
}


//**** 通常の起動 ***********************************************************************

//---- OnBootイベント -------------------------------------------------------------------
OnBoot
{
	起動共通スクリプト
	--
	// 挨拶処理
	挨拶
}

//---- 朝/昼/夜などをおおざっぱに調べる関数 -------------------------------------------
GetTimeSlot
{
	if hour >= 4 && hour <= 11
	{
		"朝"
	}
	elseif hour >= 12 && hour <= 14
	{
		"昼"
	}
	elseif hour >= 15 && hour <= 17
	{
		"日中"
	}
	elseif hour >= 18 && hour <= 21
	{
		"夜"
	}
	else
	{
		"深夜"
	}
}


//**** 終了 *****************************************************************************

//---- OnCloseイベント ------------------------------------------------------------------
OnClose
{
	"\1\s[10]終わりですか。\w5\0"
	--
	_timeslot = GetTimeSlot
	if _timeslot == "朝"
	{
		//---- 朝に終了
		"\s[0]徹夜明けかな？\w6\n\s[5]おやすみなさい。"
	}
	elseif _timeslot == "昼" || _timeslot == "日中"
	{
		//---- 昼/日中に終了
		"\s[5]じゃあ、またね。"
		"\s[5]さよなら。"
	}
	else
	{
		//---- 夜/深夜に終了
		"\s[5]おやすみなさい。"
	}
	--
	"\-\e"
}


//**** 最小化からの復帰 *****************************************************************

//---- OnWindowStateRestoreイベント -----------------------------------------------------
OnWindowStateRestore
{
	"\1\s[10]やれやれ・・・\0\s[0]\e"
	"\0\s[4]ふー、復帰だよ。\1\s[10]ええ。\e"
}


//**** シェル切り替え **********************************************************

//---- シェルチェンジ開始 ---------------------------------------------------------------
OnShellChanging
{
	"\0\s[0]着替え中・・・\e"
}

//---- シェルチェンジ完了 ---------------------------------------------------------------
OnShellChanged
{
	"\0\s[5]%reference0シェルに替わりました。\w5\nどう、%username？\e"
}