//******************************************************************************
// YAYA　ゴーストテンプレート
// メニュー処理辞書
//******************************************************************************

//******************************************************************************
//メインメニューの展開
//
//メニューの使い方
//1つめの文字列＝選択肢に表示する文字列
//2つめの文字列＝選んだときに実行される関数名
//3つめの文字列＝改行する量　50%刻み　省略すると100%（＝\n）
//******************************************************************************

//------------------------------------------------------------------------------
//メインメニュー展開
//------------------------------------------------------------------------------
OpenMenu
{
	"\0\s[5]なんか御用やろか？"
	"\0\s[5]なんです？"
	"\0\s[0]どないしたん？"
	--
	'\_q\n\n[half]'
	--
	半分メニュー開始()
	--
	半分メニュー("しゃべれ！","Menu_AITALK",200)
	--
	if ( STRLEN(AYATEMPLATE.LastTalk) > 0 ) {
		半分メニュー("さっきの！","Menu_LASTTALK")
	}
	--
	半分メニュー終了()
	--
	半分メニュー開始()
	--
	半分メニュー("にゅーす！","Menu_NEWS")
	--
	半分メニュー("おねがい！","Menu_CONFIG")
	--
	半分メニュー終了()
	--
	'\n[half]'
	--
	メニュー("きゃんせる！","Menu_CANCEL")
	--
	'\_q'
}

//------------------------------------------------------------------------------
//メニュー選択タイムアウト
//------------------------------------------------------------------------------
選択肢時間切れ
{
	"\0\s[3]いまいち、選ぶ気になれへんかった？\e"
}


//******************************************************************************
//各項目の処理内容
//******************************************************************************

//---- 何か話して
Menu_AITALK
{
	//---- 明示的にAIトーク開始を指示
	OnAiTalk
}

//---- さっきの話は
Menu_LASTTALK
{
	AYATEMPLATE.LastTalk
}

Menu_CONFIG
{
	'\0\s[5]ええよ、なんでも聞くよぉ。'
	--
	'\_q\n\n[half]'
	--
	メニュー("しゃべり頻度を変えて","Menu_TALKINTERVAL") + '\n'
	--
	メニュー("名前を覚えて","Menu_NAMEINPUT") + '\n\n[half]'
	--
	メニュー("戻る","OpenMenu") + '\n'
	--
	メニュー("なんでもない","Menu_CANCEL")
	--
	'\_q'
}

//---- トーク頻度の調整
Menu_TALKINTERVAL
{
	"\0\s[0]どのくらいがええ？"
	--
	メニュー("うるさいくらい","Menu_TALKMAX",200)
	--
	メニュー("ふつう","Menu_TALKNORMAL")
	--
	メニュー("静か","Menu_TALKPOOR")
	--
	メニュー("黙ってて","Menu_TALKNONE")
	--
	メニュー("戻る","OpenMenu",150)
}


//---- トーク頻度
Menu_TALKMAX
{
	//---- うるさく話す(15秒間隔)
	aitalkinterval = 15
	<<"
ち０３	「ほいでは、関西のオバチャン化します。」
へ	「……その言い方だと萌え要素が無くなる。」
	">>
}

Menu_TALKNORMAL
{
	//---- ふつうに話す(3分間隔)
	aitalkinterval = 180
	<<"
ち０５	「ふつーのちなちゃんやで。」
へ	「萌えないのも普通。」
ち０３	「ほっといてや。」
	">>
}

Menu_TALKPOOR
{
	//---- 静かに話す(5分間隔)
	aitalkinterval = 300
	<<"
ち０６	「思い出したように喋れと言う。」
へ	「その方がネタが切れなくていい。」
ち	「……ネタを考えるのも、大変なんよ？」
	">>
}

Menu_TALKNONE
{
	//---- 話さない
	aitalkinterval = 0
	<<"
ち２０	「……喋りな女の子、嫌いなんやろか。」
へ	「……忙しいんだろ。」
	">>
}

//---- キャンセルされた
Menu_CANCEL
{
	<<"
ち０３	「なんでやねん。」
	">>
	<<"
ち０３	「…ふにゃ。」
	">>
}

//---- キャンセルされた
Menu_CANCEL_NOTALK
{
	""
}

//---- ヘッドライン
Menu_HEADLINECANCEL
{
	//---- キャンセルされた
	"\0\s[5]はーい。\e"
}

//---- 名前覚えて
Menu_NAMEINPUT
{
	名前入力起動('メニュー')
}

名前入力開くメニュー
{
	if 名前入力初期名称判定() {
		//「いまいちはっきりせん人」のとき
		<<"
		ち０７	「ええんやね？
			ほんまにそのままでええんやね？」
		">>
	}
	else {
		<<"
		ち０３	「……（ユーザー）とちゃうかったん？
			嘘言うてたん？」
		へ	「……いや、違う呼び方をしてもらいたくなったとか、
			なんでそうねじ曲がった解釈をするんだよ。
			…あ、敬称は無しでよろしくな。」
		">>
	}
}

名前入力空欄メニュー
{
	<<"
	ち０７	「申告しなおしてそれかいっ！
		ワインボトルでどついたるよ！？」
	へ１１	「まず落ち着けッ！！」
	">>
}

名前入力空欄繰り返しメニュー
{
	<<"
	ち０７	「意地でも教えんつもりかいっ！」
	">>
}

名前入力敬称メニュー
{
	<<"
	ち０５	「敬称はいらんて、何遍言うたら分かるかなぁ？」
	へ	「いいからそのワインボトルを仕舞え。」
	">>
}

名前入力終了メニュー
{
	<<"
	ち０６	「次の偽名は、（ユーザー）。ちなおぼえた。」
	へ	「…お前なー。」
	">>
}